Launch GHO on Avalanche

.gitmodules

@@ -1,3 +1,10 @@
 [submodule "lib/aave-helpers"]
 	path = lib/aave-helpers
 	url = https://github.com/bgd-labs/aave-helpers
+[submodule "lib/ccip"]
+	path = lib/ccip
+	url = https://github.com/aave/ccip.git
+	branch = feat/1_5_token_pool
+[submodule "lib/gho-core"]
+	path = lib/gho-core
+	url = https://github.com/aave/gho-core.git

foundry.toml

@@ -2,7 +2,7 @@
 src = 'src'
 test = 'tests'
 script = 'scripts'
-solc = '0.8.20'
+solc = '0.8.24'
 out = 'out'
 bytecode_hash = 'none'
 libs = ['lib']

remappings.txt

@@ -3,3 +3,5 @@ aave-helpers/=lib/aave-helpers/
 aave-v3-origin/=lib/aave-helpers/lib/aave-address-book/lib/aave-v3-origin/src/
 forge-std/=lib/aave-helpers/lib/forge-std/src/
 solidity-utils/=lib/aave-helpers/lib/aave-address-book/lib/aave-v3-origin/lib/solidity-utils/src
+ccip/=lib/ccip/contracts/src/v0.8/ccip/
+gho-core/=lib/gho-core/src/contracts/

src/20241106_Multi_GHOAvaxLaunch/AaveV3Arbitrum_GHOAvaxLaunch_20241106.sol

@@ -0,0 +1,100 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {UpgradeableBurnMintTokenPool} from 'ccip/pools/GHO/UpgradeableBurnMintTokenPool.sol';
+import {UpgradeableTokenPool} from 'ccip/pools/GHO/UpgradeableTokenPool.sol';
+import {RateLimiter} from 'ccip/libraries/RateLimiter.sol';
+import {TokenAdminRegistry} from 'ccip/tokenAdminRegistry/TokenAdminRegistry.sol';
+import {IProposalGenericExecutor} from 'aave-helpers/src/interfaces/IProposalGenericExecutor.sol';
+import {AaveV3ArbitrumAssets} from 'aave-address-book/AaveV3Arbitrum.sol';
+import {GovernanceV3Arbitrum} from 'aave-address-book/GovernanceV3Arbitrum.sol';
+import {IGhoToken} from 'gho-core/gho/interfaces/IGhoToken.sol';
+
+/**
+ * @title GHOAvaxLaunch
+ * @author Aave Labs
+ * - Snapshot: https://snapshot.org/#/aave.eth/proposal/0x2aed7eb8b03cb3f961cbf790bf2e2e1e449f841a4ad8bdbcdd223bb6ac69e719
+ * - Discussion: https://governance.aave.com/t/arfc-launch-gho-on-avalanche-set-aci-as-emissions-manager-for-rewards/19339
+ * @dev This payload consists of the following set of actions:
+ * 1. Accept ownership of CCIP TokenPool
+ * 2. Configure CCIP TokenPool for Ethereum
+ * 3. Configure CCIP TokenPool for Avalanche
+ * 4. Add CCIP TokenPool as GHO Facilitator (allowing burn and mint)
+ * 5. Accept administrator role from Chainlink token admin registry
+ * 6. Link token to pool on Chainlink token admin registry
+ */
+contract AaveV3Arbitrum_GHOAvaxLaunch_20241106 is IProposalGenericExecutor {
+  address public constant CCIP_RMN_PROXY = 0xC311a21e6fEf769344EB1515588B9d535662a145;
+  address public constant CCIP_ROUTER = 0x141fa059441E0ca23ce184B6A78bafD2A517DdE8;
+  // TODO: Wait for token admin registry to be deployed, and get proper address
+  address public constant CCIP_TOKEN_ADMIN_REGISTRY = 0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419;
+  // TODO: Wait until new token pool is deployed on Arbitrum, then use corresponding address
+  address public constant CCIP_TOKEN_POOL = 0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419;
+  uint256 public constant CCIP_BUCKET_CAPACITY = 1_000_000e18; // 1M
+  uint64 public constant CCIP_ETH_CHAIN_SELECTOR = 5009297550715157269;
+  uint64 public constant CCIP_AVAX_CHAIN_SELECTOR = 6433500567565415381;
+
+  function execute() external {
+    // 1. Accept TokenPool ownership
+    UpgradeableBurnMintTokenPool(CCIP_TOKEN_POOL).acceptOwnership();
+
+    // 2. Configure CCIP TokenPool for Ethereum
+    // TODO: Set remote pool and token addresses after deployment?
+    _configureCcipTokenPool(CCIP_TOKEN_POOL, CCIP_ETH_CHAIN_SELECTOR, address(0), address(0));
+
+    // 3. Configure CCIP TokenPool for Avalanche
+    // TODO: Set remote pool and token addresses after deployment?
+    _configureCcipTokenPool(CCIP_TOKEN_POOL, CCIP_AVAX_CHAIN_SELECTOR, address(0), address(0));
+
+    // 4. Add CCIP TokenPool as GHO Facilitator
+    IGhoToken(AaveV3ArbitrumAssets.GHO_UNDERLYING).grantRole(
+      IGhoToken(AaveV3ArbitrumAssets.GHO_UNDERLYING).FACILITATOR_MANAGER_ROLE(),
+      GovernanceV3Arbitrum.EXECUTOR_LVL_1
+    );
+    IGhoToken(AaveV3ArbitrumAssets.GHO_UNDERLYING).grantRole(
+      IGhoToken(AaveV3ArbitrumAssets.GHO_UNDERLYING).BUCKET_MANAGER_ROLE(),
+      GovernanceV3Arbitrum.EXECUTOR_LVL_1
+    );
+    IGhoToken(AaveV3ArbitrumAssets.GHO_UNDERLYING).addFacilitator(
+      CCIP_TOKEN_POOL,
+      'CCIP TokenPool',
+      uint128(CCIP_BUCKET_CAPACITY)
+    );
+
+    // 5. Accept administrator role from Chainlink token manager
+    TokenAdminRegistry(CCIP_TOKEN_ADMIN_REGISTRY).acceptAdminRole(
+      AaveV3ArbitrumAssets.GHO_UNDERLYING
+    );
+
+    // 6. Link token to pool on Chainlink token admin registry
+    TokenAdminRegistry(CCIP_TOKEN_ADMIN_REGISTRY).setPool(
+      AaveV3ArbitrumAssets.GHO_UNDERLYING,
+      CCIP_TOKEN_POOL
+    );
+  }
+
+  function _configureCcipTokenPool(
+    address tokenPool,
+    uint64 chainSelector,
+    address remotePool,
+    address remoteToken
+  ) internal {
+    UpgradeableTokenPool.ChainUpdate[] memory chainUpdates = new UpgradeableTokenPool.ChainUpdate[](
+      1
+    );
+    RateLimiter.Config memory rateConfig = RateLimiter.Config({
+      isEnabled: false,
+      capacity: 0,
+      rate: 0
+    });
+    chainUpdates[0] = UpgradeableTokenPool.ChainUpdate({
+      remoteChainSelector: chainSelector,
+      allowed: true,
+      remotePoolAddress: abi.encode(remotePool),
+      remoteTokenAddress: abi.encode(remoteToken),
+      outboundRateLimiterConfig: rateConfig,
+      inboundRateLimiterConfig: rateConfig
+    });
+    UpgradeableBurnMintTokenPool(tokenPool).applyChainUpdates(chainUpdates);
+  }
+}

src/20241106_Multi_GHOAvaxLaunch/AaveV3Arbitrum_GHOAvaxLaunch_20241106.t.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {AaveV3Arbitrum} from 'aave-address-book/AaveV3Arbitrum.sol';
+
+import 'forge-std/Test.sol';
+import {ProtocolV3TestBase, ReserveConfig} from 'aave-helpers/src/ProtocolV3TestBase.sol';
+import {AaveV3Arbitrum_GHOAvaxLaunch_20241106} from './AaveV3Arbitrum_GHOAvaxLaunch_20241106.sol';
+
+/**
+ * @dev Test for AaveV3Arbitrum_GHOAvaxLaunch_20241106
+ * command: FOUNDRY_PROFILE=arbitrum forge test --match-path=src/20241106_Multi_GHOAvaxLaunch/AaveV3Arbitrum_GHOAvaxLaunch_20241106.t.sol -vv
+ */
+contract AaveV3Arbitrum_GHOAvaxLaunch_20241106_Test is ProtocolV3TestBase {
+  AaveV3Arbitrum_GHOAvaxLaunch_20241106 internal proposal;
+
+  function setUp() public {
+    vm.createSelectFork(vm.rpcUrl('arbitrum'), 271862002);
+    proposal = new AaveV3Arbitrum_GHOAvaxLaunch_20241106();
+  }
+
+  /**
+   * @dev executes the generic test suite including e2e and config snapshots
+   */
+  function test_defaultProposalExecution() public {
+    defaultTest('AaveV3Arbitrum_GHOAvaxLaunch_20241106', AaveV3Arbitrum.POOL, address(proposal));
+  }
+}

src/20241106_Multi_GHOAvaxLaunch/AaveV3Avalanche_GHOAvaxLaunch_20241106.sol

@@ -0,0 +1,172 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {TransparentUpgradeableProxy} from 'solidity-utils/contracts/transparent-proxy/TransparentUpgradeableProxy.sol';
+import {IERC20} from 'solidity-utils/contracts/oz-common/interfaces/IERC20.sol';
+import {SafeERC20} from 'solidity-utils/contracts/oz-common/SafeERC20.sol';
+import {UpgradeableBurnMintTokenPool} from 'ccip/pools/GHO/UpgradeableBurnMintTokenPool.sol';
+import {UpgradeableTokenPool} from 'ccip/pools/GHO/UpgradeableTokenPool.sol';
+import {RateLimiter} from 'ccip/libraries/RateLimiter.sol';
+import {TokenAdminRegistry} from 'ccip/tokenAdminRegistry/TokenAdminRegistry.sol';
+import {IProposalGenericExecutor} from 'aave-helpers/src/interfaces/IProposalGenericExecutor.sol';
+import {AaveV3PayloadAvalanche} from 'aave-helpers/src/v3-config-engine/AaveV3PayloadAvalanche.sol';
+import {AaveV3Avalanche} from 'aave-address-book/AaveV3Avalanche.sol';
+import {GovernanceV3Avalanche} from 'aave-address-book/GovernanceV3Avalanche.sol';
+import {MiscAvalanche} from 'aave-address-book/MiscAvalanche.sol';
+import {EngineFlags} from 'aave-v3-origin/contracts/extensions/v3-config-engine/EngineFlags.sol';
+import {IAaveV3ConfigEngine} from 'aave-v3-origin/contracts/extensions/v3-config-engine/IAaveV3ConfigEngine.sol';
+import {UpgradeableGhoToken} from 'gho-core/gho/UpgradeableGhoToken.sol';
+import {IGhoToken} from 'gho-core/gho/interfaces/IGhoToken.sol';
+
+/**
+ * @title GHO Avax Launch
+ * @author Aave Labs
+ * - Snapshot: https://snapshot.org/#/aave.eth/proposal/0x2aed7eb8b03cb3f961cbf790bf2e2e1e449f841a4ad8bdbcdd223bb6ac69e719
+ * - Discussion: https://governance.aave.com/t/arfc-launch-gho-on-avalanche-set-aci-as-emissions-manager-for-rewards/19339
+ * @dev This payload consists of the following set of actions:
+ * 1. Deploy GHO
+ * 2. Accept ownership of CCIP TokenPool
+ * 3. Configure CCIP TokenPool for Ethereum
+ * 4. Configure CCIP TokenPool for Arbitrum
+ * 5. Add CCIP TokenPool as GHO Facilitator (allowing burn and mint)
+ * 6. Accept administrator role from Chainlink token admin registry
+ * 7. Link token to pool on Chainlink token admin registry
+ */
+contract AaveV3Avalanche_GHOAvaxLaunch_20241106 is IProposalGenericExecutor {
+  address public constant CCIP_RMN_PROXY = 0xcBD48A8eB077381c3c4Eb36b402d7283aB2b11Bc;
+  address public constant CCIP_ROUTER = 0xF4c7E640EdA248ef95972845a62bdC74237805dB;
+  // TODO: Wait for token admin registry to be deployed, and get proper address
+  address public constant CCIP_TOKEN_ADMIN_REGISTRY = 0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419;
+  // TODO: Wait until new token pool is deployed on Avalanche, then use corresponding address
+  address public constant CCIP_TOKEN_POOL = 0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419;
+  uint256 public constant CCIP_BUCKET_CAPACITY = 25_000_000e18; // 25M
+  uint64 public constant CCIP_ETH_CHAIN_SELECTOR = 5009297550715157269;
+  uint64 public constant CCIP_ARB_CHAIN_SELECTOR = 4949039107694359620;
+
+  function execute() external {
+    // 1. Deploy GHO
+    address ghoToken = _deployGhoToken();
+
+    // 2. Accept TokenPool ownership
+    UpgradeableBurnMintTokenPool(CCIP_TOKEN_POOL).acceptOwnership();
+
+    // 3. Configure CCIP TokenPool for Ethereum
+    // TODO: Set remote pool and token addresses after deployment?
+    _configureCcipTokenPool(CCIP_TOKEN_POOL, CCIP_ETH_CHAIN_SELECTOR, address(0), address(0));
+
+    // 4. Configure CCIP TokenPool for Arbitrum
+    // TODO: Set remote pool and token addresses after deployment?
+    _configureCcipTokenPool(CCIP_TOKEN_POOL, CCIP_ARB_CHAIN_SELECTOR, address(0), address(0));
+
+    // 5. Add CCIP TokenPool as GHO Facilitator
+    IGhoToken(ghoToken).grantRole(
+      IGhoToken(ghoToken).FACILITATOR_MANAGER_ROLE(),
+      GovernanceV3Avalanche.EXECUTOR_LVL_1
+    );
+    IGhoToken(ghoToken).grantRole(
+      IGhoToken(ghoToken).BUCKET_MANAGER_ROLE(),
+      GovernanceV3Avalanche.EXECUTOR_LVL_1
+    );
+    IGhoToken(ghoToken).addFacilitator(
+      CCIP_TOKEN_POOL,
+      'CCIP TokenPool',
+      uint128(CCIP_BUCKET_CAPACITY)
+    );
+
+    // 6. Accept administrator role from Chainlink token manager
+    TokenAdminRegistry(CCIP_TOKEN_ADMIN_REGISTRY).acceptAdminRole(ghoToken);
+
+    // 7. Link token to pool on Chainlink token admin registry
+    TokenAdminRegistry(CCIP_TOKEN_ADMIN_REGISTRY).setPool(ghoToken, CCIP_TOKEN_POOL);
+  }
+
+  function _deployGhoToken() internal returns (address) {
+    address imple = address(new UpgradeableGhoToken());
+
+    bytes memory ghoTokenInitParams = abi.encodeWithSignature(
+      'initialize(address)',
+      GovernanceV3Avalanche.EXECUTOR_LVL_1 // owner
+    );
+    return
+      address(
+        new TransparentUpgradeableProxy(imple, MiscAvalanche.PROXY_ADMIN, ghoTokenInitParams)
+      );
+  }
+
+  function _configureCcipTokenPool(
+    address tokenPool,
+    uint64 chainSelector,
+    address remotePool,
+    address remoteToken
+  ) internal {
+    UpgradeableTokenPool.ChainUpdate[] memory chainUpdates = new UpgradeableTokenPool.ChainUpdate[](
+      1
+    );
+    RateLimiter.Config memory rateConfig = RateLimiter.Config({
+      isEnabled: false,
+      capacity: 0,
+      rate: 0
+    });
+    chainUpdates[0] = UpgradeableTokenPool.ChainUpdate({
+      remoteChainSelector: chainSelector,
+      allowed: true,
+      remotePoolAddress: abi.encode(remotePool),
+      remoteTokenAddress: abi.encode(remoteToken),
+      outboundRateLimiterConfig: rateConfig,
+      inboundRateLimiterConfig: rateConfig
+    });
+    UpgradeableBurnMintTokenPool(tokenPool).applyChainUpdates(chainUpdates);
+  }
+}
+
+// TODO: Determine appropriate procedure to have these 2 as separate payload, same AIP
+/*
+ * @dev This payload consists of the following set of actions:
+ * 1. List GHO on Avax in separate payload - because there is a delay to activate lane
+ * 2. Supply GHO to the Aave protocol
+ */
+contract GhoAvaxListing is AaveV3PayloadAvalanche {
+  using SafeERC20 for IERC20;
+
+  uint256 public constant GHO_SEED_AMOUNT = 1_000_000e18;
+  address public ghoToken;
+
+  constructor(address gho) {
+    ghoToken = gho;
+  }
+
+  function newListings() public view override returns (IAaveV3ConfigEngine.Listing[] memory) {
+    IAaveV3ConfigEngine.Listing[] memory listings = new IAaveV3ConfigEngine.Listing[](1);
+
+    listings[0] = IAaveV3ConfigEngine.Listing({
+      asset: ghoToken,
+      assetSymbol: 'GHO',
+      priceFeed: 0xB05984aD83C20b3ADE7bf97a9a0Cb539DDE28DBb, // TODO: Correct price feed
+      enabledToBorrow: EngineFlags.ENABLED,
+      borrowableInIsolation: EngineFlags.DISABLED,
+      withSiloedBorrowing: EngineFlags.DISABLED,
+      flashloanable: EngineFlags.ENABLED,
+      ltv: 0,
+      liqThreshold: 0,
+      liqBonus: 0,
+      reserveFactor: 10_00,
+      supplyCap: 5_000_000,
+      borrowCap: 4_500_000,
+      debtCeiling: 0,
+      liqProtocolFee: 0,
+      rateStrategyParams: IAaveV3ConfigEngine.InterestRateInputData({
+        optimalUsageRatio: _bpsToRay(90_00),
+        baseVariableBorrowRate: _bpsToRay(0),
+        variableRateSlope1: _bpsToRay(12_00),
+        variableRateSlope2: _bpsToRay(65_00)
+      })
+    });
+
+    return listings;
+  }
+
+  function _postExecute() internal override {
+    IERC20(ghoToken).forceApprove(address(AaveV3Avalanche.POOL), GHO_SEED_AMOUNT);
+    AaveV3Avalanche.POOL.supply(ghoToken, GHO_SEED_AMOUNT, address(0), 0);
+  }
+}

src/20241106_Multi_GHOAvaxLaunch/AaveV3Avalanche_GHOAvaxLaunch_20241106.t.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {AaveV3Avalanche} from 'aave-address-book/AaveV3Avalanche.sol';
+
+import 'forge-std/Test.sol';
+import {ProtocolV3TestBase, ReserveConfig} from 'aave-helpers/src/ProtocolV3TestBase.sol';
+import {AaveV3Avalanche_GHOAvaxLaunch_20241106} from './AaveV3Avalanche_GHOAvaxLaunch_20241106.sol';
+
+/**
+ * @dev Test for AaveV3Avalanche_GHOAvaxLaunch_20241106
+ * command: FOUNDRY_PROFILE=avalanche forge test --match-path=src/20241106_Multi_GHOAvaxLaunch/AaveV3Avalanche_GHOAvaxLaunch_20241106.t.sol -vv
+ */
+contract AaveV3Avalanche_GHOAvaxLaunch_20241106_Test is ProtocolV3TestBase {
+  AaveV3Avalanche_GHOAvaxLaunch_20241106 internal proposal;
+
+  function setUp() public {
+    vm.createSelectFork(vm.rpcUrl('avalanche'), 52758592);
+    proposal = new AaveV3Avalanche_GHOAvaxLaunch_20241106();
+  }
+
+  /**
+   * @dev executes the generic test suite including e2e and config snapshots
+   */
+  function test_defaultProposalExecution() public {
+    defaultTest('AaveV3Avalanche_GHOAvaxLaunch_20241106', AaveV3Avalanche.POOL, address(proposal));
+  }
+}