feat: rewrite in nushell

DEVELOPING.md

@@ -0,0 +1,4 @@
+# Developing
+
+## i18n
+Run `xnutext rhino-pkg **/*.nu -o po/rhino-pkg.pot` after adding new translatable text.

Makefile

@@ -4,4 +4,6 @@ all: install
 
 install:
 	mapfile -t linguas <po/LINGUAS && for i in "$${linguas[@]}"; do mkdir -p $(DESTDIR)/usr/share/locale/"$${i}"/LC_MESSAGES/ && msgfmt -o $(DESTDIR)/usr/share/locale/"$${i}"/LC_MESSAGES/rhino-pkg.mo po/"$${i}".po; done
+	mkdir -pv $(DESTDIR)/usr/share/rhino-pkg/
+	cp -rv modules/ $(DESTDIR)/usr/share/rhino-pkg/
 	install -Dm755 rhino-pkg -t $(DESTDIR)/usr/bin/

README.md

@@ -5,35 +5,35 @@ A package manager wrapper for Pacstall, APT, Flatpak and snap.
 
 ### Usage
 ```
-USAGE: rhino-pkg [function] {flag} <input>                                                  
+USAGE: rhino-pkg [function] {flag} <input>
 
 functions:
-    install: Install package(s) - Prompts user to respond with 
+    install: Install package(s) - Prompts user to respond with
              the number(s) associated with the desired package(s).
-             
+
     remove:  Uninstall package(s) - Prompts user to respond with
              the number(s) associated with the desired package(s).
-             
+
     search:  Search for package(s) - Does not have a second prompt.
-    
+
     update:  Updates all packages accessible to the wrapper - does
-             not accept <input>, instead use install to update 
+             not accept <input>, instead use install to update
              individual packages. Has a confirmation prompt.
 
     cleanup: Attempts to repair broken dependencies and remove any
-             unused packages. Does not accept <input>, but has 
+             unused packages. Does not accept <input>, but has
              a confirmation prompt.
 
-flags: 
+flags:
     --help/-h: Display this page
-    
-    --description/-d: By default, rhino-pkg will only display packages 
-    that contain <input> within their name. Use this flag to increase 
+
+    --description/-d: By default, rhino-pkg will only display packages
+    that contain <input> within their name. Use this flag to increase
     range and display packages with <input> in their description.
 
     -y: Makes functions with confirmation prompts run promptless.
-    
-input: 
+
+input:
     Provide a package name or description.
 
 Example execution:

docs/adding_new_plug.md

@@ -0,0 +1,5 @@
+# Adding new package manager plug
+
+1. Add a color to `modules/lib/cmd.nu`.
+2. Add an entry to `modules/pluggables/mod.nu`.
+2. Copy one of the files from `modules/pluggables/` and add it.

modules/lib/cmd.nu

@@ -0,0 +1,135 @@
+export def exists [cmd: string] : nothing -> bool {
+    ((which $cmd | length) > 0)
+}
+
+# Return color based off of package manager
+export def print-color [type: string] {
+    match $type {
+        "pacstall" => (ansi yellow_bold)
+        "apt" => (ansi green_bold)
+        "flatpak" => (ansi cyan_bold)
+        "snap" => (ansi red_bold)
+        _ => (ansi grey_bold)
+    }
+}
+
+export def prompt [ask: string, pkgs: list] : nothing -> table {
+    let input = (input $"($ask) [0-(($pkgs | length) - 1)]: ")
+    if ($input | is-empty) {
+        [($pkgs | enumerate).0.item]
+    } else {
+        let parsed = ($input
+            | split row ' '
+            | find --regex "[0-9]+" --regex "^[0-9]+"
+            | into int
+            | filter {|key| $key in 0..<($pkgs | length)}
+        )
+        if ($parsed | is-empty) {
+            tprint -e "No valid inputs given"
+            exit 1
+        }
+        $pkgs
+            | enumerate
+            | where index in $parsed
+            | flatten
+    }
+}
+
+export def install-pkg [
+        pkg: record,
+        promptless: bool
+    ] {
+    match $pkg.provider {
+        "pacstall" => {
+            if $promptless {
+                ^pacstall -PI $"($pkg.pkg)@($pkg.repo)"
+            } else {
+                ^pacstall -I $"($pkg.pkg)@($pkg.repo)"
+            }
+        }
+        "apt" => {
+            if $promptless {
+                ^sudo apt-get install $pkg.pkg -y
+            } else {
+                ^sudo apt-get install $pkg.pkg
+            }
+        }
+        "flatpak" => {
+            if $promptless {
+                ^flatpak install $pkg.remote $pkg.pkg -y
+            } else {
+                ^flatpak install $pkg.remote $pkg.pkg
+            }
+        }
+        # So snap is weird because some packages need classic installation
+        # ref: [https://github.com/rhino-linux/rhino-pkg/issues/46].
+        # But on the plus side it doesn't have the ability for -y.
+        "snap" => {
+            if ($pkg.Notes == "classic") {
+                ^sudo snap install --classic $pkg.pkg
+            } else {
+                ^sudo snap install $pkg.pkg
+            }
+        }
+    }
+}
+
+export def remove-pkg [
+        pkg: record,
+        promptless: bool
+    ] {
+    match $pkg.provider {
+        "pacstall" => {
+            if $promptless {
+                ^pacstall -PR $pkg.pkg
+            } else {
+                ^pacstall -R $pkg.pkg
+            }
+        }
+        "apt" => {
+            if $promptless {
+                ^sudo apt-get remove $pkg.pkg -y
+            } else {
+                ^sudo apt-get remove $pkg.pkg
+            }
+        }
+        "flatpak" => {
+            if $promptless {
+                ^flatpak remove $pkg.pkg -y
+            } else {
+                ^flatpak remove $pkg.pkg
+            }
+        }
+        "snap" => {
+            ^sudo snap remove $pkg.pkg --purge
+        }
+    }
+}
+
+export def cleanup-pkg [promptless: bool] {
+    if $promptless {
+        if (exists "apt") {
+            ^sudo apt-get --fix-broken install
+            ^sudo apt-get apt-remove -y
+        }
+        if (exists "flatpak") {
+            ^sudo flatpak repair
+            ^sudo flatpak uninstall --unused -y
+        }
+    } else {
+        if (exists "apt") {
+            ^sudo apt-get --fix-broken install
+            ^sudo apt-get apt-remove
+        }
+        if (exists "flatpak") {
+            ^sudo flatpak repair
+            ^sudo flatpak uninstall --unused
+        }
+    }
+    if (exists "snap") {
+        ^snap list --all
+            | detect columns
+            | where Notes =~ "disabled"
+            | each {|pkg| ^sudo snap remove $pkg.Name --revision=($pkg.Version)}
+    }
+}

modules/lib/mod.nu

@@ -0,0 +1,3 @@
+export module screen.nu
+export module cmd.nu
+export module search.nu

modules/lib/screen.nu

@@ -0,0 +1,5 @@
+# Clear screen with tput
+export def clearscr [] {
+    ^tput cuu 1
+    ^tput el
+}

modules/lib/search.nu

@@ -0,0 +1,53 @@
+use "/usr/share/rhino-pkg/modules/lib/screen.nu" [clearscr]
+use "/usr/share/rhino-pkg/modules/lib/cmd.nu" [print-color]
+
+export def search-pkgs [
+    description: bool
+    rest: string
+] : nothing -> table {
+    use "/usr/share/rhino-pkg/modules/pluggables/" [pacstall flatpak apt snap]
+    tprint "Searching Pacstall…"
+    let pac_results = (pacstall search $rest $description)
+    clearscr
+    tprint "Searching flatpak…"
+    let flatpak_results = (flatpak search $rest $description)
+    clearscr
+    tprint "Searching apt…"
+    let apt_results = (apt search $rest $description)
+    tprint "Searching snap…"
+    let snap_results = (snap search $rest $description)
+    clearscr
+    let total = $snap_results | append $flatpak_results | append $apt_results | append $pac_results
+    mut idx = 0
+    for bla in $total {
+        let le_color = (print-color $bla.provider)
+        print $"[($le_color)($idx)(ansi reset)]: ($bla.pkg) \(($le_color)($bla.provider)(ansi reset)\)"
+        $idx += 1
+    }
+    # Just because someone else might need the table.
+    return $total
+}
+
+export def search-local-pkgs [search: string] : nothing -> table {
+    use "/usr/share/rhino-pkg/modules/pluggables/" [pacstall flatpak apt snap]
+    tprint "Searching Pacstall…"
+    let pac_results = (pacstall list-installed $search)
+    clearscr
+    print "Searching flatpak…"
+    let flatpak_results = (flatpak list-installed $search)
+    clearscr
+    tprint "Searching apt…"
+    let apt_results = (apt list-installed $search)
+    tprint "Searching snap…"
+    let snap_results = (snap list-installed $search)
+    clearscr
+    let total = $snap_results | append $flatpak_results | append $apt_results | append $pac_results
+    mut idx = 0
+    for bla in $total {
+        let le_color = (print-color $bla.provider)
+        print $"[($le_color)($idx)(ansi reset)]: ($bla.pkg) ~ (ansi defb)($bla.version)(ansi reset) \(($le_color)($bla.provider)(ansi reset)\)"
+        $idx += 1
+    }
+    # Just because someone else might need the table.
+    return $total
+}

modules/pluggables/apt.nu

@@ -0,0 +1,42 @@
+use "/usr/share/rhino-pkg/modules/lib/cmd.nu" [exists]
+
+export def list-installed [search: string] {
+    if (exists "aptitude") {
+        ^aptitude search $"~i($search) !?section\(Pacstall\)" -F '%p|%v'
+            | lines
+            | parse "{pkg}|{version}"
+            | insert provider "apt"
+    }
+}
+
+export def search [input: string, description: bool] : nothing -> table {
+    if (exists "aptitude") {
+        if $description {
+            # We are searching for something in description
+            ^aptitude search --quiet --disable-columns $"?name\(($input)\) | ?description\(($input)\) ?architecture\(native\) !?section\(Pacstall\)" -F "%p|%d"
+                | lines
+                | parse "{pkg}|{desc}"
+                | insert provider 'apt'
+        } else {
+            ^aptitude search --quiet --disable-columns $"?name\(($input)\) ?architecture\(native\) !?section\(Pacstall\)" -F "%p"
+                | lines
+                | parse "{pkg}"
+                | insert desc ''
+                | insert provider 'apt'
+        }
+    } else {
+        []
+    }
+}
+
+export def upgrade [promptless: bool] {
+    if (exists "apt") {
+        if $promptless {
+            ^sudo apt update -y
+            ^sudo apt upgrade -y
+        } else {
+            ^sudo apt update
+            ^sudo apt upgrade
+        }
+    }
+}

modules/pluggables/flatpak.nu

@@ -0,0 +1,39 @@
+use "/usr/share/rhino-pkg/modules/lib/cmd.nu" [exists]
+
+export def list-installed [search: string] {
+    if (exists "flatpak") {
+        ^flatpak list --columns=application:f,version:f --app
+            | lines
+            | uniq
+            | parse "{pkg}\t{version}"
+            | where pkg =~ $search
+            | insert provider "flatpak"
+    }
+}
+
+export def search [input: string, description: bool] : nothing -> table {
+    # Description here is a dummy flag, because flatpak searches by both name and description with no way
+    # to change that afaik.
+    if (exists "flatpak") {
+        ^flatpak search $input --columns=application:f,remotes:f
+            | lines
+            | parse -r '^([\w.-]+)\s+(\w+)$'
+            | rename pkg remote
+            | insert provider 'flatpak'
+            | merge (^flatpak search $input --columns=description:f
+                | lines
+                | wrap 'desc')
+    } else {
+        []
+    }
+}
+
+export def upgrade [promptless: bool] {
+    if (exists "flatpak") {
+        if $promptless {
+            ^flatpak update -y
+        } else {
+            ^flatpak update
+        }
+    }
+}

modules/pluggables/mod.nu

@@ -0,0 +1,5 @@
+# Apparently this is how it works
+export module pacstall.nu
+export module flatpak.nu
+export module apt.nu
+export module snap.nu