Chainlink for ERC4626 factorized

src/ChainlinkOracle.sol

@@ -4,16 +4,22 @@ pragma solidity 0.8.19;
 import {IOracle} from "morpho-blue/interfaces/IOracle.sol";
 
 import {AggregatorV3Interface, ChainlinkDataFeedLib} from "./libraries/ChainlinkDataFeedLib.sol";
+import {IERC4626, VaultLib} from "./libraries/VaultLib.sol";
 
 /// @title ChainlinkOracle
 /// @author Morpho Labs
 /// @custom:contact [email protected]
 /// @notice Morpho Blue oracle using Chainlink-compliant feeds.
 contract ChainlinkOracle is IOracle {
+    using VaultLib for IERC4626;
     using ChainlinkDataFeedLib for AggregatorV3Interface;
 
     /* IMMUTABLES */
 
+    /// @notice Vault.
+    IERC4626 public immutable VAULT;
+    /// @notice Vault decimals.
+    uint256 public immutable VAULT_DECIMALS;
     /// @notice First base feed.
     AggregatorV3Interface public immutable BASE_FEED_1;
     /// @notice Second base feed.
@@ -27,20 +33,27 @@ contract ChainlinkOracle is IOracle {
 
     /* CONSTRUCTOR */
 
+    /// @param vault Vault. Pass address zero to omit this parameter.
     /// @param baseFeed1 First base feed. Pass address zero if the price = 1.
     /// @param baseFeed2 Second base feed. Pass address zero if the price = 1.
     /// @param quoteFeed1 First quote feed. Pass address zero if the price = 1.
     /// @param quoteFeed2 Second quote feed. Pass address zero if the price = 1.
     /// @param baseTokenDecimals Base token decimals.
     /// @param quoteTokenDecimals Quote token decimals.
     constructor(
+        IERC4626 vault,
         AggregatorV3Interface baseFeed1,
         AggregatorV3Interface baseFeed2,
         AggregatorV3Interface quoteFeed1,
         AggregatorV3Interface quoteFeed2,
         uint256 baseTokenDecimals,
         uint256 quoteTokenDecimals
     ) {
+        // The vault parameter is used for ERC4626 tokens, to price its shares.
+        // It is used to price a full unit of the vault shares, so it requires dividing by that number, hence the
+        // `VAULT_DECIMALS` subtraction in the following `SCALE_FACTOR` definition.
+        VAULT = vault;
+        VAULT_DECIMALS = VAULT.getDecimals();
         BASE_FEED_1 = baseFeed1;
         BASE_FEED_2 = baseFeed2;
         QUOTE_FEED_1 = quoteFeed1;
@@ -62,15 +75,15 @@ contract ChainlinkOracle is IOracle {
         SCALE_FACTOR = 10
             ** (
                 36 + quoteTokenDecimals + quoteFeed1.getDecimals() + quoteFeed2.getDecimals() - baseTokenDecimals
-                    - baseFeed1.getDecimals() - baseFeed2.getDecimals()
+                    - baseFeed1.getDecimals() - baseFeed2.getDecimals() - VAULT_DECIMALS
             );
     }
 
     /* PRICE */
 
     /// @inheritdoc IOracle
     function price() external view returns (uint256) {
-        return (BASE_FEED_1.getPrice() * BASE_FEED_2.getPrice() * SCALE_FACTOR)
+        return (VAULT.getAssets(10 ** VAULT_DECIMALS) * BASE_FEED_1.getPrice() * BASE_FEED_2.getPrice() * SCALE_FACTOR)
             / (QUOTE_FEED_1.getPrice() * QUOTE_FEED_2.getPrice());
     }
 }

src/interfaces/IERC4626.sol

@@ -0,0 +1,7 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.0;
+
+interface IERC4626 {
+    function convertToAssets(uint256) external view returns (uint256);
+    function decimals() external view returns (uint256);
+}

src/libraries/VaultLib.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.0;
+
+import {IERC4626} from "../interfaces/IERC4626.sol";
+
+/// @title ChainlinkDataFeedLib
+/// @author Morpho Labs
+/// @custom:contact [email protected]
+/// @notice Library exposing functions to price shares of an ERC4626 vault.
+library VaultLib {
+    /// @dev Converts `shares` into the corresponding assets on the `vault`.
+    /// @dev When `vault` is the address zero, returns 1.
+    function getAssets(IERC4626 vault, uint256 shares) internal view returns (uint256) {
+        if (address(vault) == address(0)) return 1;
+
+        return vault.convertToAssets(shares);
+    }
+
+    /// @dev Returns the number of decimals of a `vault`, seen as an ERC20.
+    /// @dev When `vault` is the address zero, returns 0.
+    function getDecimals(IERC4626 vault) internal view returns (uint256) {
+        if (address(vault) == address(0)) return 0;
+
+        return vault.decimals();
+    }
+}

test/ChainlinkOracleTest.sol

@@ -21,14 +21,19 @@ AggregatorV3Interface constant stEthEthFeed = AggregatorV3Interface(0x86392dC19c
 AggregatorV3Interface constant usdcEthFeed = AggregatorV3Interface(0x986b5E1e1755e3C2440e960477f25201B0a8bbD4);
 // 8 decimals of precision
 AggregatorV3Interface constant ethUsdFeed = AggregatorV3Interface(0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419);
+// 18 decimals of precision
+AggregatorV3Interface constant daiEthFeed = AggregatorV3Interface(0x773616E4d11A78F511299002da57A0a94577F1f4);
+
+IERC4626 constant vaultZero = IERC4626(address(0));
+IERC4626 constant sDaiVault = IERC4626(0x83F20F44975D03b1b09e64809B757c47f942BEeA);
 
 contract ChainlinkOracleTest is Test {
     function setUp() public {
         vm.createSelectFork(vm.envString("ETH_RPC_URL"));
     }
 
     function testOracleWbtcUsdc() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(wBtcBtcFeed, btcUsdFeed, usdcUsdFeed, feedZero, 8, 6);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, wBtcBtcFeed, btcUsdFeed, usdcUsdFeed, feedZero, 8, 6);
         (, int256 firstBaseAnswer,,,) = wBtcBtcFeed.latestRoundData();
         (, int256 secondBaseAnswer,,,) = btcUsdFeed.latestRoundData();
         (, int256 quoteAnswer,,,) = usdcUsdFeed.latestRoundData();
@@ -40,7 +45,7 @@ contract ChainlinkOracleTest is Test {
     }
 
     function testOracleUsdcWbtc() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(usdcUsdFeed, feedZero, wBtcBtcFeed, btcUsdFeed, 6, 8);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, usdcUsdFeed, feedZero, wBtcBtcFeed, btcUsdFeed, 6, 8);
         (, int256 baseAnswer,,,) = usdcUsdFeed.latestRoundData();
         (, int256 firstQuoteAnswer,,,) = wBtcBtcFeed.latestRoundData();
         (, int256 secondQuoteAnswer,,,) = btcUsdFeed.latestRoundData();
@@ -52,51 +57,76 @@ contract ChainlinkOracleTest is Test {
     }
 
     function testOracleWbtcEth() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(wBtcBtcFeed, btcEthFeed, feedZero, feedZero, 8, 18);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero,wBtcBtcFeed, btcEthFeed, feedZero, feedZero, 8, 18);
         (, int256 firstBaseAnswer,,,) = wBtcBtcFeed.latestRoundData();
         (, int256 secondBaseAnswer,,,) = btcEthFeed.latestRoundData();
         assertEq(oracle.price(), (uint256(firstBaseAnswer) * uint256(secondBaseAnswer) * 10 ** (36 + 18 - 8 - 8 - 18)));
     }
 
     function testOracleStEthUsdc() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(stEthEthFeed, feedZero, usdcEthFeed, feedZero, 18, 6);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, stEthEthFeed, feedZero, usdcEthFeed, feedZero, 18, 6);
         (, int256 baseAnswer,,,) = stEthEthFeed.latestRoundData();
         (, int256 quoteAnswer,,,) = usdcEthFeed.latestRoundData();
         assertEq(oracle.price(), uint256(baseAnswer) * 10 ** (36 + 18 + 6 - 18 - 18) / uint256(quoteAnswer));
     }
 
     function testOracleEthUsd() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(ethUsdFeed, feedZero, feedZero, feedZero, 18, 0);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, ethUsdFeed, feedZero, feedZero, feedZero, 18, 0);
         (, int256 expectedPrice,,,) = ethUsdFeed.latestRoundData();
         assertEq(oracle.price(), uint256(expectedPrice) * 10 ** (36 - 18 - 8));
     }
 
     function testOracleStEthEth() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(stEthEthFeed, feedZero, feedZero, feedZero, 18, 18);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, stEthEthFeed, feedZero, feedZero, feedZero, 18, 18);
         (, int256 expectedPrice,,,) = stEthEthFeed.latestRoundData();
         assertEq(oracle.price(), uint256(expectedPrice) * 10 ** (36 + 18 - 18 - 18));
         assertApproxEqRel(oracle.price(), 1e36, 0.01 ether);
     }
 
     function testOracleEthStEth() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(feedZero, feedZero, stEthEthFeed, feedZero, 18, 18);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, feedZero, feedZero, stEthEthFeed, feedZero, 18, 18);
         (, int256 expectedPrice,,,) = stEthEthFeed.latestRoundData();
         assertEq(oracle.price(), 10 ** (36 + 18 + 18 - 18) / uint256(expectedPrice));
         assertApproxEqRel(oracle.price(), 1e36, 0.01 ether);
     }
 
     function testOracleUsdcUsd() public {
-        ChainlinkOracle oracle = new ChainlinkOracle(usdcUsdFeed, feedZero, feedZero, feedZero, 6, 0);
+        ChainlinkOracle oracle = new ChainlinkOracle(vaultZero, usdcUsdFeed, feedZero, feedZero, feedZero, 6, 0);
         assertApproxEqRel(oracle.price(), 1e36 / 1e6, 0.01 ether);
     }
 
     function testNegativeAnswer(int256 price) public {
         price = bound(price, type(int256).min, -1);
         ChainlinkAggregatorMock aggregator = new ChainlinkAggregatorMock();
         ChainlinkOracle oracle =
-            new ChainlinkOracle(AggregatorV3Interface(address(aggregator)), feedZero, feedZero, feedZero, 18, 0);
+        new ChainlinkOracle(vaultZero, AggregatorV3Interface(address(aggregator)), feedZero, feedZero, feedZero, 18, 0);
         aggregator.setAnwser(price);
         vm.expectRevert(bytes(ErrorsLib.NEGATIVE_ANSWER));
         oracle.price();
     }
+
+    function testSDaiEthOracle() public {
+        ChainlinkOracle oracle = new ChainlinkOracle(sDaiVault, daiEthFeed, feedZero, feedZero, feedZero, 18, 18);
+        (, int256 expectedPrice,,,) = daiEthFeed.latestRoundData();
+        assertEq(
+            oracle.price(),
+            sDaiVault.convertToAssets(1e18) * uint256(expectedPrice) * 10 ** (36 + 18 + 0 - 18 - 18 - 18)
+        );
+    }
+
+    function testSDaiUsdcOracle() public {
+        ChainlinkOracle oracle = new ChainlinkOracle(sDaiVault, daiEthFeed, feedZero, usdcEthFeed, feedZero, 18, 6);
+        (, int256 baseAnswer,,,) = daiEthFeed.latestRoundData();
+        (, int256 quoteAnswer,,,) = usdcEthFeed.latestRoundData();
+        assertEq(
+            oracle.price(),
+            sDaiVault.convertToAssets(1e18) * uint256(baseAnswer) * 10 ** (36 + 6 + 18 - 18 - 18 - 18)
+                / uint256(quoteAnswer)
+        );
+        // DAI has 12 more decimals than USDC.
+        uint256 expectedPrice = 10 ** (36 - 12);
+        // Admit a 50% interest gain before breaking this test.
+        uint256 deviation = 0.5 ether;
+        assertApproxEqRel(oracle.price(), expectedPrice, deviation);
+    }
 }