Feat/withdrawal credentials

contracts/0.8.9/WithdrawalVault.sol

@@ -9,6 +9,9 @@
 import "@openzeppelin/contracts-v4.4/token/ERC20/utils/SafeERC20.sol";
 
 import {Versioned} from "./utils/Versioned.sol";
+import {AccessControlEnumerable} from "./utils/access/AccessControlEnumerable.sol";
+import {TriggerableWithdrawals} from "./lib/TriggerableWithdrawals.sol";
+import { ILidoLocator } from "../common/interfaces/ILidoLocator.sol";
 
 interface ILido {
     /**
@@ -22,12 +25,14 @@
 /**
  * @title A vault for temporary storage of withdrawals
  */
-contract WithdrawalVault is Versioned {
+contract WithdrawalVault is AccessControlEnumerable, Versioned {
     using SafeERC20 for IERC20;
 
     ILido public immutable LIDO;
     address public immutable TREASURY;
 
+    bytes32 public constant ADD_FULL_WITHDRAWAL_REQUEST_ROLE = keccak256("ADD_FULL_WITHDRAWAL_REQUEST_ROLE");
+
     // Events
     /**
      * Emitted when the ERC20 `token` recovered (i.e. transferred)
@@ -42,34 +47,44 @@
     event ERC721Recovered(address indexed requestedBy, address indexed token, uint256 tokenId);
 
     // Errors
-    error LidoZeroAddress();
-    error TreasuryZeroAddress();
+    error ZeroAddress();
     error NotLido();
     error NotEnoughEther(uint256 requested, uint256 balance);
     error ZeroAmount();
 
+    error InsufficientTriggerableWithdrawalFee(uint256 providedTotalFee, uint256 requiredTotalFee, uint256 requestCount);
+
     /**
      * @param _lido the Lido token (stETH) address
      * @param _treasury the Lido treasury address (see ERC20/ERC721-recovery interfaces)
      */
-    constructor(ILido _lido, address _treasury) {
-        if (address(_lido) == address(0)) {
-            revert LidoZeroAddress();
-        }
-        if (_treasury == address(0)) {
-            revert TreasuryZeroAddress();
-        }
+    constructor(address _lido, address _treasury) {
+        _requireNonZero(_lido);
+        _requireNonZero(_treasury);
 
-        LIDO = _lido;
+        LIDO = ILido(_lido);
         TREASURY = _treasury;
     }
 
-    /**
-     * @notice Initialize the contract explicitly.
-     * Sets the contract version to '1'.
-     */
-    function initialize() external {
-        _initializeContractVersionTo(1);
+    /// @notice Initializes the contract. Can be called only once.
+    /// @param _admin Lido DAO Aragon agent contract address.
+    /// @dev Proxy initialization method.
+    function initialize(address _admin) external {
+        // Initializations for v0 --> v2
+        _checkContractVersion(0);
+
+        _initialize_v2(_admin);
+        _initializeContractVersionTo(2);
+    }
+
+    /// @notice Finalizes upgrade to v2 (from v1). Can be called only once.
+    /// @param _admin Lido DAO Aragon agent contract address.
+    function finalizeUpgrade_v2(address _admin) external {
+        // Finalization for v1 --> v2
+        _checkContractVersion(1);
+
+        _initialize_v2(_admin);
+        _updateContractVersion(2);
     }
 
     /**
@@ -122,4 +137,44 @@
 
         _token.transferFrom(address(this), TREASURY, _tokenId);
     }
+
+    /**
+     * @dev Adds full withdrawal requests for the provided public keys.
+     *      The validator will fully withdraw and exit its duties as a validator.
+     * @param pubkeys An array of public keys for the validators requesting full withdrawals.
+     */
+    function addFullWithdrawalRequests(
+        bytes[] calldata pubkeys
+    ) external payable onlyRole(ADD_FULL_WITHDRAWAL_REQUEST_ROLE) {
+        uint256 prevBalance = address(this).balance - msg.value;
+
+        uint256 minFeePerRequest = TriggerableWithdrawals.getWithdrawalRequestFee();
+        uint256 totalFee = pubkeys.length * minFeePerRequest;
+
+        if(totalFee > msg.value) {
+            revert InsufficientTriggerableWithdrawalFee(msg.value, totalFee, pubkeys.length);
+        }
+
+        TriggerableWithdrawals.addFullWithdrawalRequests(pubkeys, minFeePerRequest);
+
+        uint256 refund = msg.value - totalFee;
+        if (refund > 0) {
+            msg.sender.call{value: refund}("");
+        }
+
+        assert(address(this).balance == prevBalance);
+    }
+
+    function getWithdrawalRequestFee() external view returns (uint256) {
+        return TriggerableWithdrawals.getWithdrawalRequestFee();
+    }
+
+    function _requireNonZero(address _address) internal pure {
+        if (_address == address(0)) revert ZeroAddress();
+    }
+
+    function _initialize_v2(address _admin) internal {
+        _requireNonZero(_admin);
+        _setupRole(DEFAULT_ADMIN_ROLE, _admin);
+    }
 }

contracts/0.8.9/lib/TriggerableWithdrawals.sol

@@ -0,0 +1,140 @@
+// SPDX-FileCopyrightText: 2023 Lido <[email protected]>
+// SPDX-License-Identifier: GPL-3.0
+
+pragma solidity 0.8.9;
+
+library TriggerableWithdrawals {
+    address constant WITHDRAWAL_REQUEST = 0x0c15F14308530b7CDB8460094BbB9cC28b9AaaAA;
+
+    error MismatchedArrayLengths(uint256 keysCount, uint256 amountsCount);
+    error InsufficientBalance(uint256 balance, uint256 totalWithdrawalFee);
+    error InsufficientRequestFee(uint256 feePerRequest, uint256 minFeePerRequest);
+
+    error WithdrawalRequestFeeReadFailed();
+    error InvalidPubkeyLength(bytes pubkey);
+    error WithdrawalRequestAdditionFailed(bytes pubkey, uint256 amount);
+    error NoWithdrawalRequests();
+    error PartialWithdrawalRequired(bytes pubkey);
+
+    event WithdrawalRequestAdded(bytes pubkey, uint256 amount);
+
+    /**
+     * @dev Adds full withdrawal requests for the provided public keys.
+     *      The validator will fully withdraw and exit its duties as a validator.
+     * @param pubkeys An array of public keys for the validators requesting full withdrawals.
+     */
+    function addFullWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint256 feePerRequest
+    ) internal {
+        uint64[] memory amounts = new uint64[](pubkeys.length);
+        _addWithdrawalRequests(pubkeys, amounts, feePerRequest);
+    }
+
+    /**
+     * @dev Adds partial withdrawal requests for the provided public keys with corresponding amounts.
+     *      A partial withdrawal is any withdrawal where the amount is greater than zero.
+     *      A full withdrawal is any withdrawal where the amount is zero.
+     *      This allows withdrawal of any balance exceeding 32 ETH (e.g., if a validator has 35 ETH, up to 3 ETH can be withdrawn).
+     *      However, the protocol enforces a minimum balance of 32 ETH per validator, even if a higher amount is requested.
+     * @param pubkeys An array of public keys for the validators requesting withdrawals.
+     * @param amounts An array of corresponding withdrawal amounts for each public key.
+     */
+    function addPartialWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint64[] calldata amounts,
+        uint256 feePerRequest
+    ) internal {
+        _requireArrayLengthsMatch(pubkeys, amounts);
+
+        for (uint256 i = 0; i < amounts.length; i++) {
+            if (amounts[i] == 0) {
+                revert PartialWithdrawalRequired(pubkeys[i]);
+            }
+        }
+
+        _addWithdrawalRequests(pubkeys, amounts, feePerRequest);
+    }
+
+        /**
+     * @dev Adds partial or full withdrawal requests for the provided public keys with corresponding amounts.
+     *      A partial withdrawal is any withdrawal where the amount is greater than zero.
+     *      This allows withdrawal of any balance exceeding 32 ETH (e.g., if a validator has 35 ETH, up to 3 ETH can be withdrawn).
+     *      However, the protocol enforces a minimum balance of 32 ETH per validator, even if a higher amount is requested.
+     * @param pubkeys An array of public keys for the validators requesting withdrawals.
+     * @param amounts An array of corresponding withdrawal amounts for each public key.
+     */
+    function addWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint64[] calldata amounts,
+        uint256 feePerRequest
+    ) internal {
+        _requireArrayLengthsMatch(pubkeys, amounts);
+        _addWithdrawalRequests(pubkeys, amounts, feePerRequest);
+    }
+
+    /**
+     * @dev Retrieves the current withdrawal request fee.
+     * @return The minimum fee required per withdrawal request.
+     */
+    function getWithdrawalRequestFee() internal view returns (uint256) {
+        (bool success, bytes memory feeData) = WITHDRAWAL_REQUEST.staticcall("");
+
+        if (!success) {
+            revert WithdrawalRequestFeeReadFailed();
+        }
+
+        return abi.decode(feeData, (uint256));
+    }
+
+    function _addWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint64[] memory amounts,
+        uint256 feePerRequest
+    ) internal {
+        uint256 keysCount = pubkeys.length;
+        if (keysCount == 0) {
+            revert NoWithdrawalRequests();
+        }
+
+        uint256 minFeePerRequest = getWithdrawalRequestFee();
+
+        if (feePerRequest == 0) {
+            feePerRequest = minFeePerRequest;
+        }
+
+        if (feePerRequest < minFeePerRequest) {
+            revert InsufficientRequestFee(feePerRequest, minFeePerRequest);
+        }
+
+        uint256 totalWithdrawalFee = feePerRequest * keysCount;
+
+        if(address(this).balance < totalWithdrawalFee) {
+            revert InsufficientBalance(address(this).balance, totalWithdrawalFee);
+        }
+
+        for (uint256 i = 0; i < keysCount; ++i) {
+            if(pubkeys[i].length != 48) {
+                revert InvalidPubkeyLength(pubkeys[i]);
+            }
+
+            bytes memory callData = abi.encodePacked(pubkeys[i], amounts[i]);
+            (bool success, ) = WITHDRAWAL_REQUEST.call{value: feePerRequest}(callData);
+
+            if (!success) {
+                revert WithdrawalRequestAdditionFailed(pubkeys[i], amounts[i]);
+            }
+
+            emit WithdrawalRequestAdded(pubkeys[i], amounts[i]);
+        }
+    }
+
+    function _requireArrayLengthsMatch(
+        bytes[] calldata pubkeys,
+        uint64[] calldata amounts
+    ) internal pure {
+        if (pubkeys.length != amounts.length) {
+            revert MismatchedArrayLengths(pubkeys.length, amounts.length);
+        }
+    }
+}

scripts/scratch/steps/0120-initialize-non-aragon-contracts.ts

@@ -35,6 +35,7 @@ export async function main() {
   const exitBusOracleAdmin = testnetAdmin;
   const stakingRouterAdmin = testnetAdmin;
   const withdrawalQueueAdmin = testnetAdmin;
+  const withdrawalVaultAdmin = testnetAdmin;
 
   // Initialize NodeOperatorsRegistry
 
@@ -108,6 +109,10 @@ export async function main() {
     { from: deployer },
   );
 
+  // Initialize WithdrawalVault
+  const withdrawalVault = await loadContract("WithdrawalVault", withdrawalVaultAddress);
+  await makeTx(withdrawalVault, "initialize", [withdrawalVaultAdmin], { from: deployer });
+
   // Initialize WithdrawalQueue
   const withdrawalQueue = await loadContract("WithdrawalQueueERC721", withdrawalQueueAddress);
   await makeTx(withdrawalQueue, "initialize", [withdrawalQueueAdmin], { from: deployer });

test/0.8.9/contracts/TriggerableWithdrawals_Harness.sol

@@ -0,0 +1,38 @@
+pragma solidity 0.8.9;
+
+import {TriggerableWithdrawals} from "contracts/0.8.9/lib/TriggerableWithdrawals.sol";
+
+contract TriggerableWithdrawals_Harness {
+    function addFullWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint256 feePerRequest
+    ) external {
+        TriggerableWithdrawals.addFullWithdrawalRequests(pubkeys, feePerRequest);
+    }
+
+    function addPartialWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint64[] calldata amounts,
+        uint256 feePerRequest
+    ) external {
+        TriggerableWithdrawals.addPartialWithdrawalRequests(pubkeys, amounts, feePerRequest);
+    }
+
+    function addWithdrawalRequests(
+        bytes[] calldata pubkeys,
+        uint64[] calldata amounts,
+        uint256 feePerRequest
+    ) external {
+        TriggerableWithdrawals.addWithdrawalRequests(pubkeys, amounts, feePerRequest);
+    }
+
+    function getWithdrawalRequestFee() external view returns (uint256) {
+        return TriggerableWithdrawals.getWithdrawalRequestFee();
+    }
+
+    function getWithdrawalsContractAddress() public pure returns (address) {
+        return TriggerableWithdrawals.WITHDRAWAL_REQUEST;
+    }
+
+    function deposit() external payable {}
+}

test/0.8.9/contracts/WithdrawalVault__Harness.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: UNLICENSED
+// for testing purposes only
+
+pragma solidity 0.8.9;
+
+import {WithdrawalVault} from "contracts/0.8.9/WithdrawalVault.sol";
+
+contract WithdrawalVault__Harness is WithdrawalVault {
+    constructor(address _lido, address _treasury) WithdrawalVault(_lido, _treasury) {
+    }
+
+    function harness__initializeContractVersionTo(uint256 _version) external {
+        _initializeContractVersionTo(_version);
+    }
+}

test/0.8.9/contracts/predeployed/WithdrawalsPredeployed_Mock.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity 0.8.9;
+
+/**
+ * @notice This is an mock of EIP-7002's pre-deploy contract.
+ */
+contract WithdrawalsPredeployed_Mock {
+    uint256 public fee;
+    bool public failOnAddRequest;
+    bool public failOnGetFee;
+
+    event eip7002WithdrawalRequestAdded(bytes request, uint256 fee);
+
+    function setFailOnAddRequest(bool _failOnAddRequest) external {
+        failOnAddRequest = _failOnAddRequest;
+    }
+
+    function setFailOnGetFee(bool _failOnGetFee) external {
+        failOnGetFee = _failOnGetFee;
+    }
+
+    function setFee(uint256 _fee) external {
+        require(_fee > 0, "fee must be greater than 0");
+        fee = _fee;
+    }
+
+    fallback(bytes calldata input) external payable returns (bytes memory output){
+        if (input.length == 0) {
+            require(!failOnGetFee, "fail on get fee");
+
+            output = abi.encode(fee);
+            return output;
+        }
+
+        require(!failOnAddRequest, "fail on add request");
+
+        require(input.length == 56, "Invalid callData length");
+
+        emit eip7002WithdrawalRequestAdded(
+            input,
+            msg.value
+        );
+    }
+}