Add advanced query language support.

[koculu]

ZoneTree.FullTextSearch Query Language Documentation

Grammar Definition

<query>            ::= <expression>

<expression>       ::= <term> (("AND" | "OR" | "&" | "|") <term>)*

<term>             ::= ("NOT" | "-") <factor>
                    | <factor>
                    | <not_in_expression>
                    | <in_expression>

<factor>           ::= <keyword>
                    | <facet_expressions>
                    | <facet_in_expression>
                    | <facet_not_in_expression>
                    | "(" <expression> ")"

<facet_expressions> ::= <facet_expression> ( <facet_expression> )*

<facet_expression> ::= <single_keyword> ":" <single_keyword>

<keyword>          ::= <phrase> | <word> ( <word> )*

<keyword_list>     ::= "[" <keyword> ("," <keyword>)* "]"

<not_in_expression> ::= "NOT IN" <keyword_list>

<in_expression> ::= "IN" <keyword_list>

<facet_in_expression> ::= <keyword> "IN" <keyword_list>

<facet_not_in_expression> ::= <keyword> "NOT IN" <keyword_list>

<single_keyword>   ::= <word> | <phrase>

<word> ::= <word_char>+

<word_char> ::= [^\s:,()\[\]&|\\-]+
             | "\\" <any_char>

<phrase> ::= "\"" <word> ( <word> )* "\""
          |  "'" <word> ( <word> )* "'"