Member self rotation

Makefile

@@ -11,7 +11,7 @@ coverage                :; forge coverage
 gas                     :; forge test --gas-report
 gas-check               :; forge snapshot --check --tolerance 1
 snapshot                :; forge snapshot
-test-unit               :; forge test -vvv
+test-unit               :; ARB_RPC_URL=https://arb1.arbitrum.io/rpc forge test -vvv
 clean                   :; forge clean
 fmt                     :; forge fmt
 gen-network             :; yarn gen:network

src/gov-action-contracts/AIPs/SecurityCouncilMgmt/RotateMembersUpgradeAction.sol

@@ -0,0 +1,49 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity 0.8.16;
+
+import "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
+import "../../address-registries/L2AddressRegistryInterfaces.sol";
+import "@openzeppelin/contracts-upgradeable/access/IAccessControlUpgradeable.sol";
+
+/// @notice Upgrades the sec council manager to allow member rotation and sets min rotation vars
+contract RotateMembersUpgradeAction {
+    IL2AddressRegistry public immutable l2AddressRegistry;
+    address public immutable secCouncilManagerImpl;
+    uint256 public immutable minRotationPeriod;
+    address public immutable minRotationPeriodSetter;
+
+    constructor(
+        IL2AddressRegistry _l2AddressRegistry,
+        address _secCouncilManagerImpl,
+        uint256 _minRotationPeriod,
+        address _minRotationPeriodSetter
+    ) {
+        l2AddressRegistry = _l2AddressRegistry;
+        secCouncilManagerImpl = _secCouncilManagerImpl;
+        minRotationPeriod = _minRotationPeriod;
+        minRotationPeriodSetter = _minRotationPeriodSetter;
+    }
+
+    function perform() external {
+        ISecurityCouncilManager secCouncilManager = l2AddressRegistry.securityCouncilManager();
+        l2AddressRegistry.govProxyAdmin().upgradeAndCall(
+            TransparentUpgradeableProxy(payable(address(secCouncilManager))),
+            secCouncilManagerImpl,
+            abi.encodeCall(
+                ISecurityCouncilManager(secCouncilManagerImpl).postUpgradeInit,
+                (minRotationPeriod, minRotationPeriodSetter)
+            )
+        );
+
+        require(
+            minRotationPeriod == secCouncilManager.minRotationPeriod(),
+            "RotateMembersUpgradeAction: Min rotation period not set"
+        );
+        require(
+            IAccessControlUpgradeable(address(secCouncilManager)).hasRole(
+                secCouncilManager.MIN_ROTATION_PERIOD_SETTER_ROLE(), minRotationPeriodSetter
+            ),
+            "RotateMembersUpgradeAction: Min rotation period setter not set"
+        );
+    }
+}

src/gov-action-contracts/address-registries/L2AddressRegistry.sol

@@ -1,19 +1,24 @@
 // SPDX-License-Identifier: Apache-2.0
 pragma solidity 0.8.16;
 
+import "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
 import "./L2AddressRegistryInterfaces.sol";
 
 contract L2AddressRegistry is IL2AddressRegistry {
     IL2ArbitrumGoverner public immutable coreGov;
     IL2ArbitrumGoverner public immutable treasuryGov;
     IFixedDelegateErc20Wallet public immutable treasuryWallet;
     IArbitrumDAOConstitution public immutable arbitrumDAOConstitution;
+    ProxyAdmin public immutable govProxyAdmin;
+    ISecurityCouncilNomineeElectionGovernor public immutable scNomineeElectionGovernor;
 
     constructor(
         IL2ArbitrumGoverner _coreGov,
         IL2ArbitrumGoverner _treasuryGov,
         IFixedDelegateErc20Wallet _treasuryWallet,
-        IArbitrumDAOConstitution _arbitrumDAOConstitution
+        IArbitrumDAOConstitution _arbitrumDAOConstitution,
+        ProxyAdmin _govProxyAdmin,
+        ISecurityCouncilNomineeElectionGovernor _scNomineeElectionGovernor
     ) {
         require(
             _treasuryWallet.owner() == _treasuryGov.timelock(),
@@ -27,6 +32,13 @@ contract L2AddressRegistry is IL2AddressRegistry {
         treasuryGov = _treasuryGov;
         treasuryWallet = _treasuryWallet;
         arbitrumDAOConstitution = _arbitrumDAOConstitution;
+        require(
+            _govProxyAdmin.getProxyAdmin(TransparentUpgradeableProxy(payable(address(_coreGov))))
+                == address(_govProxyAdmin),
+            "GovProxyAdmin must be proxy admin of the core governor"
+        );
+        govProxyAdmin = _govProxyAdmin;
+        scNomineeElectionGovernor = _scNomineeElectionGovernor;
     }
 
     function coreGovTimelock() external view returns (IArbitrumTimelock) {
@@ -40,4 +52,16 @@ contract L2AddressRegistry is IL2AddressRegistry {
     function l2ArbitrumToken() external view returns (IL2ArbitrumToken) {
         return IL2ArbitrumGoverner(address(coreGov)).token();
     }
+
+    function scMemberElectionGovernor()
+        external
+        view
+        returns (ISecurityCouncilMemberElectionGovernor)
+    {
+        return scNomineeElectionGovernor.securityCouncilMemberElectionGovernor();
+    }
+
+    function securityCouncilManager() external view returns (ISecurityCouncilManager) {
+        return scNomineeElectionGovernor.securityCouncilManager();
+    }
 }

src/gov-action-contracts/address-registries/L2AddressRegistryInterfaces.sol

@@ -2,11 +2,15 @@
 pragma solidity 0.8.16;
 
 import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
+import "@openzeppelin/contracts/proxy/transparent/ProxyAdmin.sol";
 import "../../interfaces/IArbitrumTimelock.sol";
 import "../../interfaces/IFixedDelegateErc20Wallet.sol";
 import "../../interfaces/IL2ArbitrumToken.sol";
 import "../../interfaces/IL2ArbitrumGovernor.sol";
 import "../../interfaces/IArbitrumDAOConstitution.sol";
+import "../../security-council-mgmt/interfaces/ISecurityCouncilManager.sol";
+import "../../security-council-mgmt/interfaces/ISecurityCouncilNomineeElectionGovernor.sol";
+import "../../security-council-mgmt/interfaces/ISecurityCouncilMemberElectionGovernor.sol";
 
 interface ICoreGovTimelockGetter {
     function coreGovTimelock() external view returns (IArbitrumTimelock);
@@ -36,12 +40,30 @@ interface IArbitrumDAOConstitutionGetter {
     function arbitrumDAOConstitution() external view returns (IArbitrumDAOConstitution);
 }
 
+interface IGovProxyAdminGetter {
+    function govProxyAdmin() external view returns (ProxyAdmin);
+}
+
+interface ISecurityCouncilGetters {
+    function securityCouncilManager() external view returns (ISecurityCouncilManager);
+    function scNomineeElectionGovernor()
+        external
+        view
+        returns (ISecurityCouncilNomineeElectionGovernor);
+    function scMemberElectionGovernor()
+        external
+        view
+        returns (ISecurityCouncilMemberElectionGovernor);
+}
+
 interface IL2AddressRegistry is
     ICoreGovGetter,
     ICoreGovTimelockGetter,
     ITreasuryGovTimelockGetter,
     IDaoTreasuryGetter,
     ITreasuryGovGetter,
     IL2ArbitrumTokenGetter,
-    IArbitrumDAOConstitutionGetter
+    IArbitrumDAOConstitutionGetter,
+    IGovProxyAdminGetter,
+    ISecurityCouncilGetters
 {}

src/gov-action-contracts/governance/CancelTimelockAndRemoveMemberAction.sol

@@ -0,0 +1,24 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity 0.8.16;
+
+import "../address-registries/L2AddressRegistry.sol";
+import "./CancelTimelockOperation.sol";
+
+contract CancelTimelockAndRemoveMemberOAction {
+    IL2AddressRegistry public immutable l2AddressRegistry;
+
+    constructor(IL2AddressRegistry _l2AddressRegistry) {
+        l2AddressRegistry = _l2AddressRegistry;
+    }
+
+    function perform(address memberToRemove, bytes32 operationId) public {
+        // first remove the council member
+        ISecurityCouncilManager scm = l2AddressRegistry.securityCouncilManager();
+        IAccessControlUpgradeable(address(scm)).grantRole(scm.MEMBER_REMOVER_ROLE(), address(this));
+        scm.removeMember(memberToRemove);
+        IAccessControlUpgradeable(address(scm)).revokeRole(scm.MEMBER_REMOVER_ROLE(), address(this));
+
+        // then cancel the rotation operation in the timelock
+        CancelTimelockOperation.cancel(l2AddressRegistry.coreGov(), operationId);
+    }
+}

src/interfaces/IArbitrumTimelock.sol

@@ -13,4 +13,5 @@ interface IArbitrumTimelock {
     ) external;
     function getMinDelay() external view returns (uint256 duration);
     function updateDelay(uint256 newDelay) external;
+    function isOperation(bytes32 id) external view returns (bool registered);
 }