build.gradle

plugins {
    id 'com.github.johnrengelman.shadow' version '7.1.2' apply false
    id 'kr.entree.spigradle' version '2.2.3' apply false
}

allprojects {
    def targetJavaVersion = 11
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)

    group = 'kr.enak.crescendo.exclusiveserverselection'
    version = '1.0'

    apply plugin: 'java'

    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion

    java {
        if (JavaVersion.current() < javaVersion) {
            toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
        }
    }

    tasks.withType(JavaCompile).configureEach {
        if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
            options.release = targetJavaVersion
        }
        options.encoding = 'UTF-8';
    }
}

subprojects {
    if (project.name.endsWith("plugin")) {
        apply plugin: 'com.github.johnrengelman.shadow'

        jar {
            finalizedBy shadowJar
            outputs.upToDateWhen { false }
        }

        shadowJar {
            outputs.upToDateWhen { false }
        }

        processResources {
            def props = [version: version]
            inputs.properties props
            expand props
            filteringCharset 'UTF-8'
            filesMatching('bungee.yml') {
                expand props
            }
        }
    }
}