-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathxco-html.xqm
1056 lines (1009 loc) · 45.6 KB
/
xco-html.xqm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(:
: xco-html - functions creating HTML reports
:)
module namespace hl="http://www.parsqube.de/ns/xco/html";
import module namespace co="http://www.parsqube.de/ns/xco/constants"
at "xco-constants.xqm";
import module namespace cu="http://www.parsqube.de/ns/xco/custom"
at "xco-custom.xqm";
import module namespace dg="http://www.parsqube.de/ns/xco/debug"
at "xco-debug.xqm";
import module namespace dm="http://www.parsqube.de/ns/xco/domain"
at "xco-domain.xqm";
import module namespace eu="http://www.parsqube.de/ns/xco/edesc-util"
at "xco-edesc-util.xqm";
import module namespace fu="http://www.parsqube.de/ns/xco/file-util"
at "xco-file-util.xqm";
import module namespace hu="http://www.parsqube.de/ns/xco/html-util"
at "xco-html-util.xqm";
import module namespace ns="http://www.parsqube.de/ns/xco/namespace"
at "xco-namespace.xqm";
import module namespace u="http://www.parsqube.de/ns/xco/util"
at "xco-util.xqm";
declare namespace z="http://www.parsqube.de/ns/xco/structure";
declare boundary-space preserve;
(:~
: Transforms an XML report into an HTML report.
:
: If the report consists of several documents, they are written into files.
: In this case, this function returns only one of the report documents.
:
: @param xmlReport an XML report
: @param options options controlling the processing
: @return the HTML report, or part of the report
:)
declare function hl:htmlReport($reportType as xs:string,
$xmlReport as element()?,
$xmlReportDir as xs:string?,
$options as map(xs:string, item()*)?)
as element()* {
switch($reportType)
case 'contab' return hl:contabReport($xmlReport, $xmlReportDir, $options)
default return error(QName((), 'INVALID_ARG'),
'Unknown report type: '||$reportType)
};
(:~
: Transforms an edesc report into an contab report.
:
: @param report XML report, report type = "edesc"
: @param options options controlling the processing
: @return the HTML report "contab"
:)
declare function hl:contabReport($report as element()?,
$reportDir as xs:string?,
$options as map(xs:string, item()*)?)
as element()* {
let $domains := $options?domains
let $withEnumDict as xs:boolean := $options?withEnumDict
return
(: No domains defined - create a single report
(Note: reportDir only supported in case of domains) :)
if (not($domains)) then (
hl:contabReport_domain($report, (), $options),
hl:enumDict_domain($report, (), $options)[$withEnumDict]
)
(: Domains have been defined :)
else
let $domainReports := (
for $domain in $domains/domain
let $_DEBUG := trace($domain/@name, '*** Create report for domain: ')
let $domainReport :=
if ($report) then $report/z:domain[@z:id eq $domain/@id]
else
let $inputPath := dm:getInputReportPath('edesc', $reportDir, $domain, $options)
return doc($inputPath)/*
return (
$domainReport/hl:contabReport_domain(., $domain, $options),
$domainReport/hl:enumDict_domain(., $domain, $options)[$withEnumDict]
),
hl:contabReportIndex($domains/domain, $options)
)
return $domainReports[1]
};
(:~
: Transforms an edesc report or report domain into a contab report.
:
: If no domains have been defined, the function creates the complete
: report, otherwise the part corresponding to a single domain.
:
: @param report an edesc report, complete or limited to a domain
: @param domain an element describing the domain
: @param options options controlling the processing
: @return edesc html report, or a part of the report dealing with a domain
:)
declare function hl:contabReport_domain(
$report as element(),
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element() {
let $reportFilePath := dm:getReportPath('edesc-htrml', $domain, $options)
let $head := hl:contabReport_head($reportFilePath, $domain, $options)
let $toc := hl:contabReport_toc($report, $domain, $options)
let $xsdDivs :=
for $schema at $schemaNr in $report/z:schema
let $schemaFileName := $schema/base-uri(.) ! replace(., '.+/', '')
let $schemaName := $schemaFileName ! replace(., '(.*)\.[^.]+$', '$1')
let $anno := $schema/z:annotation/z:documentation/string()
let $headline := ($anno, $schemaFileName)[1]
let $stypes := $schema/eu:getEdescReportSimpleTypes(.)
let $stypesTable := eu:stypesTable($stypes, $domain, $options)[$stypes]
let $tables :=
for $comp at $cnr in (
$schema/z:components/*,
$schema/z:components/*//z:complexType[@z:typeID] ! u:copyNode(.)
)
let $compNr :=
let $shift := if ($stypes) then 1 else 0
return $cnr + $shift
return
typeswitch($comp)
case element(z:complexType) |
element(z:group) |
element(z:element) return
hl:contabReport_complexComp($comp, $compNr, $schemaNr, $domain, $options)
case element(z:simpleType) return ()
case element(z:attributeGroup) return ()
case element(z:attribute) return ()
default return error('Unexpected component, elem name: '||name($comp))
return
<div class="sect1" id="schema_{$schemaName}">{
<h2>{$schemaNr}. {$headline}</h2>,
if (not($stypes)) then () else
hl:contabReport_stypes($schemaName, $schemaNr, $stypesTable),
$tables
}</div>
let $title := ($domain/processing/title/<h1>{node()}</h1>, <h1>API Content</h1>)[1]
let $htmlReport :=
<html lang="en" xml:lang="en">{
$head,
<body>{
<div id="header">{
$title,
$toc
}</div>,
<div id="content">{
$xsdDivs
}</div>
}</body>
}</html>
! u:prettyNode(.)
let $_WRITE :=
let $reportPath := dm:getReportPath('contab', $domain, $options)
where ($reportPath)
return u:writeXmlDoc($reportPath, $htmlReport)
return $htmlReport
};
(:~
: Returns a <div> element containing a TOC.
:)
declare function hl:contabReport_toc(
$report as element(),
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element() {
let $custom := $options?custom
let $xsdDict := $options?schemas return
<div class="toc" id="toc">
<div id="toctitle">Table of Contents</div>
<ul class="sectlevel1">{
for $schema at $snr in $report/z:schema
let $baseUri := $schema/base-uri(.)
let $xsd := $options?schemas($baseUri)
let $schemaFileName := $baseUri ! file:name(.)
let $schemaName := $schemaFileName ! replace(., '(.*)\.[^.]+$', '$1')
let $xsdTitle := cu:xsdTitle($schema/@filePath ! $xsdDict(.),
'contab', $domain/@id, $options?custom)
let $stypes := $schema/z:components/z:simpleType
let $shift := if ($stypes) then 1 else 0
return
<li>
<a shape="rect" href="#schema_{$schemaName}">{$snr}. {$xsdTitle}</a>
<ul class="sectlevel2">{
<li>
<a shape="rect"
href="#schema_{$schemaName}_std">{$snr}.1. Simple type definitions</a>
</li>[$stypes],
for $comp at $cnr in $schema/z:components/*
[self::z:element, self::z:complexType, self::z:group]
let $compNr := $shift + $cnr
let $compKind := $comp/local-name(.)
let $name := $comp/@z:name/string()
let $dispName := cu:customComponentName(
$name, $compKind, 'main', 'contab', $domain/@id, $custom)
let $ttp := (
typeswitch($comp)
case element(z:element) return 'The toplevel element~~element.'
case element(z:complexType) return 'The complexType~~type.'
case element(z:group) return 'The ~group~group.'
default return error()
) => tokenize('~')
let $txt1 := $ttp[1]
let $txt2 := $ttp[2]
let $idPrefix := $ttp[3]
return
<li>
<a shape="rect"
href="#{$idPrefix}{$name}">{$snr}.{$compNr} {$txt1} <code>{$dispName}</code>{$txt2}
</a>
</li>
}</ul>
</li>
}</ul>
</div>
};
(:~
: Returns the head part of a contab report page.
:
: @param report XML report
: @param reportPath the file path where this document will be written
: @param domain the current domain
: @param options options controlling the processing
: @return component descriptors
:)
declare function hl:contabReport_head(
$reportPath as xs:string,
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element() {
let $title := ($domain/processing/title/string(), 'API types')[1]
let $odir := $options?odir
let $cssFilePath := $odir||'/asciidoc.css'
let $cssRelFilePath := fu:getRelPath($reportPath ! fu:getParentPath(.), $cssFilePath)
return
<head>
<title>{$title}</title>
<meta charset="UTF-8"/>
<meta http-equiv="content-type" content="text/html;charset=UTF-8"/>
<meta name="viewport" content="width=device-width, initial-scale=1.0"/>
<script type="text/javascript"><![CDATA[
document.addEventListener('DOMContentLoaded', function() {
var headers = ['h2', 'h3', 'h4', 'h5', 'h6'];
for (var i = 0; i < headers.length; i++) {
var headerElements = document.getElementsByTagName(headers[i]);
for (var j = 0; j < headerElements.length; j++) {
var header = headerElements[j];
header.innerHTML += '<a class="header-link" href="#' + header.parentNode.id + '"><span class="link-icon"></span></a>';
}
}
});
]]></script>
<link rel="stylesheet" href="https://fonts.googleapis.com/css?family=Open+Sans:300,300italic,400,400italic,600,600italic%7CNoto+Serif:400,400italic,700,700italic%7CDroid+Sans+Mono:400,700"/>,
<link rel="stylesheet" href="{$cssRelFilePath}"/>
<style><![CDATA[
.header-link {
position: relative;
font-size: 0.65em;
left: 0.5em;
opacity: 0;
-webkit-transition: opacity 0.2s ease-in-out 0.1s;
-moz-transition: opacity 0.2s ease-in-out 0.1s;
-ms-transition: opacity 0.2s ease-in-out 0.1s;
}
h2:hover .header-link,
h3:hover .header-link,
h4:hover .header-link,
h5:hover .header-link,
h6:hover .header-link {
opacity: 1;
}
.link-icon {
width: 22px;
height: 18px;
display: inline-block;
background: url("data:image/svg+xml,%3csvg xmlns='http://www.w3.org/2000/svg' viewBox='0 0 640 512'%3e%3c!--! Font Awesome Pro 6.2.0 by %40fontawesome - https://fontawesome.com License - https://fontawesome.com/license (Commercial License) Copyright 2022 Fonticons%2c Inc.--%3e%3cpath d='M579.8 267.7c56.5-56.5 56.5-148 0-204.5-50-50-128.8-56.5-186.3-15.4l-1.6 1.1c-14.4 10.3-17.7 30.3-7.4 44.6s30.3 17.7 44.6 7.4l1.6-1.1c32.1-22.9 76-19.3 103.8 8.6 31.5 31.5 31.5 82.5 0 114L422.3 334.8c-31.5 31.5-82.5 31.5-114 0-27.9-27.9-31.5-71.8-8.6-103.8l1.1-1.6c10.3-14.4 6.9-34.4-7.4-44.6s-34.4-6.9-44.6 7.4l-1.1 1.6C206.5 251.2 213 330 263 380c56.5 56.5 148 56.5 204.5 0l112.3-112.3zM60.2 244.3c-56.5 56.5-56.5 148 0 204.5 50 50 128.8 56.5 186.3 15.4l1.6-1.1c14.4-10.3 17.7-30.3 7.4-44.6s-30.3-17.7-44.6-7.4l-1.6 1.1c-32.1 22.9-76 19.3-103.8-8.6C74 372 74 321 105.5 289.5l112.2-112.3c31.5-31.5 82.5-31.5 114 0 27.9 27.9 31.5 71.8 8.6 103.9l-1.1 1.6c-10.3 14.4-6.9 34.4 7.4 44.6s34.4 6.9 44.6-7.4l1.1-1.6C433.5 260.8 427 182 377 132c-56.5-56.5-148-56.5-204.5 0L60.2 244.3z'/%3e%3c/svg%3e") no-repeat;
}
]]></style>
</head>
};
declare function hl:contabReport_stypes($schemaName,
$schemaNr,
$stypesTable)
as element(div) {
<div class="simple-type-definitions" id="schema_{$schemaName}_std">{
<h3>{$schemaNr}.1. Simple type definitions</h3>,
<div class="sectionbody">{
<table class="tableblock frame-all grid-all spread">{
<colgroup span="1">
<col span="1" style="width:28%"/>
<col span="1" style="width:28%"/>
<col span="1" style="width:44%"/>
</colgroup>,
<tbody>{
for $row in $stypesTable/*
let $nameHtml :=
let $raw := $row/name
return
if ($raw/contains(., '#')) then
hu:getLocalTypeLabelLines($raw)
else
<strong><code>{$raw/node()}</code></strong>
let $enums := $row/description/enum
let $anno := ($row/anno[string()]/string(), '-')[1]
return if (not($enums)) then
(: Case 1 - not an enum gtype :)
$row/
<tr>{
name/
<td colspan="1" rowspan="1">{
hu:classTd(),
<p id="{$row/@divId}">{
hu:classP(), $nameHtml
}</p>
}</td>,
description/
<td colspan="1" rowspan="1">{
hu:classTd(),
<p>{hu:classP(), node()}</p>
}</td>,
anno/
<td colspan="1" rowspan="1">{
hu:classTd(),
<p>{hu:classP('anno-text'), $anno}</p>
}</td>
}</tr>
(: Case 2 - enum gtype :)
else (
$row/
<tr>{
name/
<td colspan="1" rowspan="2">{
hu:classTd(),
<p id="{$row/@divId}">{
hu:classP(),
if (not(@linkName/string())) then
$nameHtml
else
<a shape="rect" href="{@linkName}">{$nameHtml}</a>
}</p>
}</td>,
anno/
<td colspan="2" rowspan="1">{
hu:classTd(),
<p>{hu:classP('anno-text'), $anno}</p>
}</td>
}</tr>,
<tr>{
<td colspan="2">{
<table>{
hu:classTable(),
<colgroup span="1">
<col span="1" style="width:28%"/>
<col span="1" style="width:72%"/>
</colgroup>,
<tbody>{
$enums/
<tr>{
<td>{
hu:classTd(),
<p>{hu:classP(), @value/string(.)}</p>
}</td>,
<td>{
hu:classTd(),
<p>{hu:classP('anno-text'),
(@anno/string()[string()], '-')[1]
}</p>
}</td>
}</tr>
}</tbody>
}</table>
}</td>
}</tr>)
}</tbody>
}</table>
}</div>
}</div>
};
(:~
: Contributes to an contab report the description of a complex
: component. A complex component can be an element declaration,
: a type definition or a group definitions.
:
: @param comp extended descriptor of a schema component
: @param compNr an ordinal number defining the position of the
: component within a sequence of components
: @param schemaNr an ordinal number defining the position of the
: containing schema withion a sequence of schemas
: @param domain an optional definition of the containing domain
: @return an HTML div element
:)
declare function hl:contabReport_complexComp(
$comp as element(),
$compNr as xs:integer,
$schemaNr as xs:integer,
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element()* {
let $custom := $options?custom
let $contentTable := eu:contentTable($comp, $domain, $options)
let $compKind := $comp/local-name(.)
let $kindName :=
switch($compKind)
case 'complexType' return 'complex type'
case 'group' return 'group'
case 'element' return 'toplevel element'
default return error()
let $idPrefix :=
switch($compKind)
case 'complexType' return 'type'
default return $comp/local-name(.)
let $name := $contentTable/@name
let $kind := $contentTable/@kind
let $typeId := $contentTable/@typeID
let $typeLabel := $contentTable/@typeLabel
let $compDisplayName :=
if ($typeLabel) then $typeLabel/string()
else
cu:customComponentName(
$name, $compKind, 'main', 'contab', $domain/@id, $custom)
let $lexName := $contentTable/@name
let $divId :=
if (not($comp/self::z:complexType/@z:typeID)) then $idPrefix||'.'||$lexName
else 'local-type.'||$comp/@z:typeID
return (
<div class="sect2" id="{$divId}">{
<h3>{$schemaNr}.{$compNr}. The {$kindName} <code>{$compDisplayName}</code></h3>,
<div class="sectionbody">{
if ($contentTable/@variant eq 'typeName') then
hl:contentHtmlTable_variant_typeName($contentTable)
else
hl:contentHtmlTable_std($contentTable, $comp, $domain, $options)
}</div>
}</div>
)
};
(:~
: Returns a table element representing the content of a complex component.
:
: @param contentTable a content table containing the essential data
: @param comp a component descriptor
: @param domain the domain containing the component
: @param options options controlling the processing
: @return a table element
:)
declare function hl:contentHtmlTable_std($contentTable as element(),
$comp as element(),
$domain as element(domain)?,
$options as map(xs:string, item()*))
as element(table) {
let $custom := $options?custom
let $compKind := $contentTable/@kind/string()
let $compAnno := $contentTable/(anno[string()]/string(), '-')[1]
let $name := $contentTable/@name
let $baseName := $contentTable/@baseName
let $baseLinkName := $contentTable/@baseLinkName
let $compositor :=
$comp/*/descendant::*[self::z:sequence, self::z:choice, self::z:choice][1]
/local-name(.)
! replace(., '.*:', '')
let $typeId := $contentTable/@typeID
let $typeLabel := $contentTable/@typeLabel
let $compDisplayName :=
if ($typeLabel) then $typeLabel/hu:getLocalTypeLabelLines(.) (: u:getDescriptorLocalTypeLabelDivs(.) :)
else
cu:customComponentName(
$name, $compKind, 'main', 'contab', $domain/@id, $custom)
! <code>{.}</code>
let $baseDisplayName :=
$baseName ! cu:customComponentName(
., $compKind, 'sub', 'contab', $domain/@id, $custom)
let $baseTypeContent := $contentTable/rows/baseTypeContent
let $typeContent := $contentTable/rows/typeContent
let $withBaseType := exists($baseTypeContent)
let $baseTypeHasItems := exists($baseTypeContent//row/name)
let $firstRowOwnContent := $typeContent/descendant::row[1][$withBaseType]
let $typeIsRestriction := $typeContent/@isRestriction eq 'yes'
return
<table>{
hu:classTable(),
hu:standardColGroup6(),
<tbody>{
(: Headline providing component name, base type name or link, component annotation
=============================================================================== :)
<tr>{
(: Component display name :)
hu:tdWithContent($compDisplayName, 4, 1)
,
(: Base type name or link :)
let $content :=
if (not($baseName)) then ()
else if (not($baseLinkName)) then <code>{$baseDisplayName}</code>
else
<a shape="rect" href="{$baseLinkName}"
title="{$baseDisplayName}">{$baseDisplayName}</a>
return hu:tdWithContent($content, 1, 1),
(: Component annotation :)
hu:tdWithContent($compAnno, 1, 1, 'anno-text')
}</tr>,
hu:tableTextLine(
('The element content starts with ', <b>items inherited</b>, ' from the base type:'),
'announceBase', ())[$withBaseType][$baseTypeHasItems]
,
(:
hu:tableTextLine(
('The element contains a ', <em>{$compositor}</em>, ' of the following elements:'))
,
:)
for $row in $contentTable//row
let $typeCategory := $row/@typeCategory
let $isComplex := $typeCategory eq 'cc'
let $displayName := $row/name/(
if (not($custom)) then . else
cu:customComponentName(
., 'element', 'sub', 'contab', $domain/@id, $custom))
let $isMandatory := not($row/occ/starts-with(., '0'))
let $fnItemName := function($name, $linkName, $isMandatory) {
let $name :=
if ($linkName) then (
text{'→'},
<a shape="rect" href="{$linkName}" title="{$displayName}">{
$displayName}</a>)
else text{$displayName}
return
if ($isMandatory) then <code><strong>{$name}</strong></code>
else <code>{$name}</code>
(:
if ($isMandatory)
then <code><strong>{$name}</strong></code>
else <code>{$name}</code>
:)
}
let $occValue := '-'[$row/branch/string()]||$row/occ
let $occTitle :=
let $min := $row/occ/substring-before(., ':')
let $max := $row/occ/substring-after(., ':')
let $piece1 := if ($min eq '0') then 'optional' else 'mandatory'
let $piece2 :=
if ($max eq '1') then 'single'
else if ($max ne '*') then 'at most '||$max
else if ($piece1 eq 'optional') then 'multiple'
else 'at least one'
let $piece3 := if ($row/branch/string()) then 'part of a choice' else ()
return string-join(($piece1, $piece2, $piece3), ', ')
(:
mandatory, at least one
mandatory, single
optional, multiple
optional, single
mandatory, at least one, part of a choice
mandatory, single, part of a choice
optional, single, part of a choice
:)
let $typeCatMarker :=
switch($typeCategory)
case 'cc' return '+'
case 'cs' return '>'
default return ()
let $startOwnContent := $row is $firstRowOwnContent
let $startOwnContentMsg :=
if (not($startOwnContent)) then ()
else if ($typeIsRestriction) then (
'Base type content is ', <i>restricted</i>, ', resulting in the following ', <b>own content</b>, ':')
else (
'Inherited content is followed by ', <b>own content</b>, ':')
let $startChoiceItems := $row/@startChoice/tokenize(., ';\s*')
return (
hu:tableTextLine($startOwnContentMsg, 'announceBase', ())[$startOwnContent]
,
if (empty($startChoiceItems)) then () else
for $startChoiceItem in $startChoiceItems
let $items := tokenize($startChoiceItem, ',\s*')
let $contextbranch := $items[starts-with(., 'contextbranch')] ! substring-after(., '=')
let $elems := $items[starts-with(., 'elems')] ! substring-after(., '=')
let $seqs := $items[starts-with(., 'seqs')] ! substring-after(., '=')
let $startText :=
if (not($contextbranch)) then 'The '
else
'In case of choice '''||$contextbranch||''', the '
let $alternatives := string-join((
$elems ! ('elements ('||$elems||')'),
$seqs ! ('element sequences ('||$seqs||')')
), ' or ')
return
hu:tableTextLine(
($startText, 'element contains ', <em>one</em>,
' of the following '||$alternatives))
,
<tr>{
$row/group/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
let $displayName :=
if (not($custom)) then . else
cu:customComponentName(
., 'group', 'sub', 'contab', $domain/@id, $custom)
return
<a shape="rect" href="{@linkName}" title="{$displayName}">{$displayName}</a>
}</td>,
$row/branch/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
<em>{string()}</em>
}</p>
}</td>,
$row/name/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
$fnItemName($displayName, @linkName, $isMandatory)
(:
if (@linkName) then $fnItemName((
text{'→'}, <a shape="rect" href="{@linkName}"
title="{$displayName}">{$displayName}</a>),
$isMandatory)
else
$fnItemName($displayName, $isMandatory)
:)
}</p>
}</td>,
$row/occ/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
if ($isMandatory) then
<code><strong title="{$occTitle}">{$occValue}</strong></code>
else
<span title="{$occTitle}">{$occValue}</span>
}</p>
}</td>,
$row/type/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
let $displayName :=
if (not($custom)) then . else
cu:customComponentName(
., 'complexType', 'sub', 'contab', $domain/@id, $custom)
return
<p>{
hu:classP(),
<em>{
if (@builtin[string()]/xs:boolean(.)) then text {string()}
else (
$typeCatMarker,
<a shape="rect" href="{@linkName}" title="{$displayName}">{$displayName}</a>
)
}</em>
}</p>
}</td>,
$row/anno/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{hu:classP('darkbrown'), string()}</p>
}</td>
}</tr>
)
}</tbody>
}</table>
};
(:~
: Returns a table element representing the content of an
: element component with a type attribute.
:
: @param contentTable a content table containing the essential data
: @param comp a component descriptor
: @param domain the domain containing the component
: @param options options controlling the processing
: @return a table element
:)
declare function hl:contentHtmlTable_variant_typeName($contentTable as element())
as element(table) {
<table>{
hu:classTable(),
hu:standardColGroup6(),
<tbody>{
$contentTable/descendant::row[1]/
<tr>{
name/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
<code>{string()}</code>
}</p>
}</td>,
type/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
if (not(@linkName/string())) then
<code>{string()}</code>
else
<em>+<a shape="rect" href="{@linkName}"
title="{string()}">{string()}</a></em>,
@substitutionGroup[string()]
! ('(', <em>↔ {string()}</em>, ')')
}</p>
}</td>,
anno/
<td colspan="{@colspan}" rowspan="{@rowspan}">{
hu:classTd(),
<p>{
hu:classP(),
string()
}</p>
}</td>
}</tr>
}</tbody>
}</table>
};
(:
: I n d e x
: =========
:)
(:~
: Writes an HTML index page, which is an entry point for
: the XSD Content Report.
:)
declare function hl:contabReportIndex(
$domains as element()*,
$options as map(xs:string, item()*))
as element(html) {
let $reportType := $options?reportType
let $odir := $options?odir
let $pageDir := $odir||'/'||$reportType
let $fileName := $reportType||'-index.html'
let $filePath := $pageDir||'/'||$fileName
let $title := <h1>{cu:systemTitleNodes('contab', $options?custom, $options)}</h1>
let $head := hl:contabReport_head($filePath, (), $options)
let $toc := hl:contabReportIndex_toc($filePath, $domains, $options)
let $htmlReport :=
<html lang="en" xml:lang="en">{
$head,
<body>{
<div id="header">{
$title,
$toc
}</div>,
<div id="content">{
}</div>
}</body>
}</html>
! u:prettyNode(.)
let $_WRITE := u:writeXmlDoc($filePath, $htmlReport)
return $htmlReport
};
(:~
: Constructs the table of content displayed by the
: XSD Content Report index page.
:)
declare function hl:contabReportIndex_toc(
$filePath as xs:string,
$domains as element()*,
$options as map(xs:string, item()*)?)
as element() {
let $dirPath := $filePath ! fu:getParentPath(.)
let $reportType := $options?reportType
let $domainDict := map:merge(
for $domain in $domains
let $filePath := dm:getReportPath('contab', $domain, $options)
let $relPath := fu:getRelPath($dirPath, $filePath)
let $fileName := $relPath ! file:name(.)
let $title := $domain/processing/title/string()
let $enumPath :=
dm:getReportPartPath('contab', 'enum-dict', $domain, $options)[file:exists(.)]
let $enumRelPath := $enumPath ! fu:getRelPath($dirPath, .)
let $enumFileName := $enumRelPath ! file:name(.)
let $countEnumTypes :=
$enumPath ! doc(.)//div[@class eq 'enum-type-definition'] => count()
return (
map:entry($relPath, map{
'filePath': $filePath,
'fileName': $fileName,
'relPath': $relPath,
'title': $title
}),
map:entry($enumRelPath, map{
'filePath': $enumPath,
'fileName': $enumFileName,
'relPath': $enumRelPath,
'title': $title||' (enumerations)',
'countEnumTypes': $countEnumTypes
})[$enumPath]
))
let $relPaths := map:keys($domainDict) => sort()
let $ftree := fu:ftree($relPaths, $dirPath)
let $linkTree := hl:contabReportIndex_tocTree($ftree, $domainDict, $options)
let $title := 'Table of Contents'
let $subtitle :=
let $reportLabel :=
if ($options?domainType eq 'xsd') then 'XSD reports' else 'reports'
return count($domains)||' '||$reportLabel
let $_DEBUG := dg:WRITE_FILE($ftree, 'FTREE.XML', 'ftree', 'yes', $options)
return
<div class="toc" id="toc">
<div id="toctitle">
<h4>{$title}</h4>
<p class="tocsubtitle">{$subtitle}</p>
</div>
<ul class="sectlevel1">{
$linkTree
}</ul>
</div>
};
(:~
: Maps a folder tree representation of report files to
: a sequence of list item elements representing folders
: and files
:
: @param ftree folder tree
: @param domainDict maps paths to domain information
: @param options options controlling the processing
:)
declare function hl:contabReportIndex_tocTree(
$ftree as element(fo),
$domainDict as map(xs:string, item()*),
$options as map(xs:string, item()*)?)
as element(li)* {
hl:contabReportIndex_tocTreeREC($ftree, $domainDict, $options)
};
declare function hl:contabReportIndex_tocTreeREC(
$n as node(),
$domainDict as map(xs:string, item()*),
$options as map(xs:string, item()*)?)
as element()* {
typeswitch($n)
case element(fo) return
let $level := count($n/ancestor::fo)
let $prefix := (for $i in 1 to $level return '>> ') => string-join('')
return (
<li>{
<span class="monospace">{$prefix}</span>,
<span class="darkbrown">{$n/@name/string()}</span>
}</li>,
$n/* ! hl:contabReportIndex_tocTreeREC(., $domainDict, $options)
)
case element(fi) return
let $href := $n/ancestor-or-self::*/@name => string-join('/')
let $isEnumDict := contains($href, 'enum-dict')
return if ($isEnumDict and not($options?withEnumDict)) then () else
let $path := $n/ancestor-or-self::*/@name => string-join('/')
let $level := count($n/ancestor::fo)
let $prefix := (for $i in 1 to $level return '. ') => string-join('')
let $dinfo := $domainDict($path)
let $href := $dinfo?relPath
let $title := $dinfo?fileName||
($dinfo?countEnumTypes[string()] ! (' ('||.||')'))
let $titleClass := attribute class {'enum-dict'}
[contains($href, 'enum-dict')]
return
<li>{
<span class="monospace">{$prefix}</span>,
<a shape="rect" href="{$href}">{$titleClass, $title}</a>
}</li>
default return ()
};
(:
: E n u m d i c t
: ==================
:)
(:~
: Transforms an edesc report or report domain into an contab report.
:
: If no domains have been defined, the function creates the complete
: report, otherwise the part corresponding to a single domain.
:
: @param report an edesc report, complete or limited to a domain
: @param domain an element describing the domain
: @param options options controlling the processing
: @return edesc html report, or a part of the report dealing with a domain
:)
declare function hl:enumDict_domain(
$report as element(),
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element()? {
if (not($report//z:enumeration)) then () else
let $_DEBUG := trace($options?withEnumDict, '_______________________WITH_ENUM_DICT: ')
let $reportFilePath := dm:getReportPartPath('contab', 'enum-dict', $domain, $options)
let $_DEBUG := trace($reportFilePath, '_REPORT_FILE_PATH: ')
let $head := hl:contabReport_head($reportFilePath, $domain, $options)
let $enumTypes := eu:getEdescReportEnumTypes($report)
let $toc := hl:contabReport_enumDict_toc($enumTypes, $domain, $options)
let $enumDivs :=
for $stype in $enumTypes
let $lname := $stype/
(@z:name/replace(., '.+:', ''), u:getLocalTypeLabel(., $options?nsmap, $options))[1]
let $globalOrLocal := if ($stype/@z:typeID) then 2 else 1
order by $globalOrLocal, $lname
count $pos
return hl:enumDict_stype($stype, $pos, $domain, $options)
let $title := ($domain/processing/titleEnumDict/<h1>{node()}</h1>,
<h1>{'Enumeration Dictionary ('||$domain/@name||')'}</h1>)[1]
let $htmlReport :=
<html lang="en" xml:lang="en">{
$head,
<body>{
<div id="header">{
$title,
$toc
}</div>,
<div id="content">{
$enumDivs
}</div>
}</body>
}</html>
! u:prettyNode(.)
let $_WRITE :=
let $reportPath := dm:getReportPartPath('contab', 'enum-dict', $domain, $options)
where ($reportPath)
return u:writeXmlDoc($reportPath, $htmlReport)
return $htmlReport
};
(:~
: Returns a <div> element containing a TOC.
:)
declare function hl:contabReport_enumDict_toc(
$enumTypes as element()*,
$domain as element(domain)?,
$options as map(xs:string, item()*)?)
as element() {
let $custom := $options?custom
let $xsdDict := $options?schemas return
<div class="toc" id="toc">
<div id="toctitle">Table of Contents - Enumeration types</div>
<ul class="sectlevel1">{
for $type at $tnr in $enumTypes
let $typeName := $type/@z:name/string()
let $typeId := $type/@z:typeID/string()
let $typeLabel := $type/u:getDescriptorLocalTypeLabel(.)
let $displayName := ($typeName, $typeLabel)[1]
let $lname := (replace($typeName, '.+:', ''), $typeLabel)[1]
let $anno :=
let $raw := $type/z:annotation/z:documentation/normalize-space(.)
! replace(., '(.*?\.).*', '$1')
return
if ($raw) then $raw
else if ($typeId) then '(Local type without documentation)'
else '(Without documentation)'
let $href :=
if ($typeName) then '#enum.'||$typeName
else '#local-enum.'||$typeId
let $globalOrLocal := if ($typeId) then 2 else 1
order by $globalOrLocal, $lname
count $tnr
return
<li>{
<a shape="rect" href="{$href}">{$tnr}. {$displayName}</a>,
text{' - '},
<em>{$anno}</em>
}</li>
}</ul>
</div>