Setting up Nixvim with HomeManager

[mmartinortiz]

Hi all,

Recently I started to manage my dotfiles with Nix. So far, I'm very happy with the results. I must admit that my Nix knowledge is quite limited, and that all my progress has been done looking to other people configs and reading some blog posts.

As part of my dotfiles, I want to add NeoVim with support for Python. My first approach was to import the package neovim and configure it based on plugins and config files.

Then, I found NixVim and decided to give it a try.

But after a couple of hours trying "just" to use it according to the Readme instructions, I'm still stuck in either Infinite recursion encountered (current status) or The option 'programs.nixvim' does not exist.

Probably, I'm doing something "obviously wrong", but I cannot identify what it is. I'd appreciate if someone can point me in the right direction. My current configuration is this branch: https://github.com/mmartinortiz/nix-conf/tree/trying-nixvim

Thanks!

[GaetanLepage]

Hi !
Welcome abroad :)
I will assume that you are trying to use nixvim with home-manage (HM).
I guess that your problem comes from either:

• where you import the nixvim home-manager module. You have to place it in the HM imports, not in the NixOS ones
• where you declare you nixvim config (i.e. where you use programs.nixvim). This should be in your HM config, not in your NixOS one.

[mmartinortiz]

Hi, thanks for your answer. Is this flake.nix correct? here is where I import nixvim

{
  description = "My Home Manager flake";

  inputs =
    {
      nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
      flake-utils = {
        url = "github:numtide/flake-utils";
      };
      home-manager =
        {
          url = "github:nix-community/home-manager";
          inputs.nixpkgs.follows = "nixpkgs";
        };
      nixvim = {
        url = "github:nix-community/nixvim";
        inputs.nixpkgs.follows = "nixpkgs";
      };
    };

  outputs =
    { nixpkgs
    , flake-utils
    , home-manager
    , ...
    }@inputs:
    let
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
    in
    {
      home-manager.imports = [
        inputs.nixvim.homeManagerModules.nixvim
      ];
      homeConfigurations = {
        manolo = home-manager.lib.homeManagerConfiguration {
          inherit pkgs;
          modules = [
            ./home-manager/home.nix
          ];
        };
      };
    };
}

Within home.nix I use the programs.nixvim.enable = true, but it still indicates that such options does not exist.

[GaetanLepage]

The inputs.nixvim.homeManagerModules.nixvim should be placed in modules (the list where you currently have ./home-manager/home.nix.

[mmartinortiz]

Thank you very much. Still too much to learn about Nix. Now, time to configure NeoVIM :-)

For other people, as reference:

{
  description = "My Home Manager flake";

  inputs =
    {
      # systems.url = "github:nix-systems/x86_64-linux";
      nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
      flake-utils = {
        url = "github:numtide/flake-utils";
        # inputs.systems.follows = "systems";
      };
      home-manager =
        {
          url = "github:nix-community/home-manager";
          inputs.nixpkgs.follows = "nixpkgs";
        };
      nixvim = {
        url = "github:nix-community/nixvim";
        # If you are not running an unstable channel of nixpkgs, select the corresponding branch of nixvim.
        # url = "github:nix-community/nixvim/nixos-23.05";
        inputs.nixpkgs.follows = "nixpkgs";
      };
    };

  outputs =
    { nixpkgs
    , flake-utils
    , home-manager
    , nixvim
    , ...
    }@inputs:
    let
      system = "x86_64-linux";
      pkgs = nixpkgs.legacyPackages.${system};
    in
    {
      homeConfigurations = {
        manolo = home-manager.lib.homeManagerConfiguration {
          inherit pkgs;
          modules = [
            nixvim.homeManagerModules.nixvim
            ./home-manager/home.nix
          ];
        };
      };
    };
}

[GaetanLepage]

Glad that it now works !

Happy hacking !