build.gradle

plugins {
    id 'java-library'
    id "com.diffplug.gradle.spotless" version "3.25.0"
}

group 'net.iaminnovative.besu'
version '1.0-SNAPSHOT'

sourceCompatibility = 11

repositories {
    jcenter()
    maven { url 'https://hyperledger-org.bintray.com/besu-repo' }
    mavenCentral()
}

ext {
    identityVersion = '1.0.5'
    akvVersion = '4.1.3'
    coreVersion = '1.5.0'
    okHttpVersion = '1.2.0'
}

configurations {
    // configuration that holds jars to include in the jar
    extraLibs
}

dependencies {
    annotationProcessor 'com.google.auto.service:auto-service:1.0-rc4'

    compileOnly 'com.google.auto.service:auto-service:1.0-rc4'
    compileOnly 'info.picocli:picocli:3.9.5'
    compileOnly 'org.apache.logging.log4j:log4j-api:2.12.0'
    compileOnly 'org.apache.logging.log4j:log4j-core:2.12.0'
    compileOnly 'org.apache.tuweni:tuweni-toml:1.0.0'
    compileOnly 'org.hyperledger.besu:plugin-api:1.4.7-SNAPSHOT'
    compileOnly 'org.hyperledger.besu.internal:crypto:1.4.7-SNAPSHOT'

    compile ("com.azure:azure-security-keyvault-secrets:$akvVersion") {
        exclude group: 'com.azure', module: 'azure-core-http-netty'
    }
    compile "com.azure:azure-identity:$identityVersion"
    compile ("com.azure:azure-core:$coreVersion") {
        exclude group: 'io.netty', module: 'netty-tcnative-boringssl-static'
    }
    compile "com.azure:azure-core-http-okhttp:$okHttpVersion"

    testImplementation 'junit:junit:4.12'
}


jar {
    archiveBaseName = project.name
    manifest {
        attributes(
                'Specification-Title': archiveBaseName.get(),
                'Specification-Version': rootProject.version,
                'Implementation-Title': archiveBaseName.get(),
                'Implementation-Version': rootProject.version
        )
    }
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    exclude 'META-INF/*.RSA', 'META-INF/*.SF', 'META-INF/*.DSA'
}