build.gradle

buildscript {
    ext.kotlin_version = '1.2.71'
    ext.kotlin_gradle_version = '1.2.71'
    ext.android_gradle_version = '3.2.0'
    ext.android_build_tools_version = '28.0.2'
    ext.byte_buddy_version = '1.9.10'
    ext.coroutines_version = '0.27.0'
    ext.dexmaker_version = '2.21.0'
    ext.objenesis_version = '3.0.1'
    ext.junit_version = '4.12'
    ext.junit_jupiter_version = '5.0.3'
    ext.junit_vintage_version = '4.12.0'
    ext.android_maven_version = '2.1'
    ext.dokka_version = '0.9.17'
    ext.gradles = project.projectDir.toString() + "/gradle"

    repositories {
        mavenCentral()
        google()
        jcenter()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_gradle_version"
        classpath "com.android.tools.build:gradle:$android_gradle_version"
        classpath "com.github.dcendents:android-maven-gradle-plugin:$android_maven_version"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokka_version"
        classpath "org.jetbrains.dokka:dokka-android-gradle-plugin:$dokka_version"
    }
}

apply from: "${gradles}/jdk6-boot.gradle"

subprojects { subProject ->
    group = 'io.mockk'

    repositories {
        mavenCentral()
        maven {
            url = "https://dl.bintray.com/linkedin/maven/"
        }
        google()
        jcenter()
    }

    apply from: "${gradles}/signing.gradle"
}