build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
	}
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'

ext.configFile = file "build.properties"

configFile.withReader {
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

ext.env = System.getenv()

// Drone.io Support
if(env.DRONE_BUILD_NUMBER)
ext.buildNumber = env.DRONE_BUILD_NUMBER

// Jenkins Support
else if (env.BUILD_NUMBER)
ext.buildNumber = env.BUILD_NUMBER

else
ext.buildNumber = config.build_number

version = "${config.minecraft_version}-${config.mod_version}.${buildNumber ?: 0}"
group = "com.iconmaster.aec" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "AetherCraft"

minecraft {
    version = config.minecraft_version + "-" + config.forge_version

    replaceIn "AetherCraft.java"
    replace "@VERSION@", "${config.mod_version}.${buildNumber ?: 0}"
}

processResources
{
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        expand 'mod_version':project.version, 'minecraft_version':project.config.minecraft_version
    }

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

repositories {
	mavenCentral()
	maven {
        name "Mobius Repo"
        url "http://mobiusstrip.eu/maven"
    }
	maven {
		name = "chickenbones"
		url = "http://chickenbones.net/maven/"
	}
	maven {
        name = "ic2"
        url = "http://maven.ic2.player.to"
    }
}

dependencies {
	compile "mcp.mobius.waila:Waila:1.5.2a"
    //compile "codechicken:CodeChickenLib:1.7.10-1.1.1.93:dev"
    //compile "codechicken:CodeChickenCore:1.7.10-1.0.2.11:dev"
    compile "net.industrial-craft:industrialcraft-2:2.2.509-experimental:api"
}