build.gradle

import java.text.SimpleDateFormat

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext.kotlin_version = '1.1.4'
    repositories {
        maven { url 'https://maven.google.com' }
        jcenter()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "org.jetbrains.kotlin:kotlin-allopen:$kotlin_version"

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        maven { url 'https://maven.google.com' }
        mavenCentral()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

def apkFolder = 'app/build/outputs/apk/rpi3/release'
def apkFilename = 'app-rpi3-release.apk'

def animationFolder = 'bundle/animations'
def animationFilename = 'bootanimation.zip'

task checkArtifacts(dependsOn: ':app:assembleRpi3Release') {

    doLast {
        def apkPath = "$apkFolder/$apkFilename"
        if (!file(apkPath).exists()) {
            throw new GradleException("App artifact missing, build must have failed ($apkPath)")
        }


        def animationPath = "$animationFolder/$animationFilename"
        if (!file(animationPath).exists()) {
            throw new GradleException("Animation asset missing, expected on $animationPath")
        }
    }

}

task bundle(type: Zip, dependsOn: ['checkArtifacts']) {

    from apkFolder
    include apkFilename

    from animationFolder
    include animationFilename

    def time = buildTime()
    def folder = 'build/outputs/bundle'
    archiveName "bundle-rpi3-${time}.zip"
    destinationDir(file(folder))

    doLast {
        println "File generated on ${folder}/${archiveName}"
    }
}

def buildTime() {
    def df = new SimpleDateFormat("yyyy-MM-dd-HHmm")
    return df.format(new Date())
}

task printHome () {
    // helps check if android studio picked up the right folders
    println gradle.gradleHomeDir
    println gradle.gradleUserHomeDir
}