build.gradle

plugins {
    id 'java'
    id 'java-library'
    id 'signing'
    id "maven-publish"
    id("io.github.gradle-nexus.publish-plugin") version "2.0.0"
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.11.0'
    testImplementation 'junit:junit:4.13.2'
    testImplementation 'org.hamcrest:hamcrest-all:1.3'
}

group = 'com.dnsimple'
version = '2.0.0'
description = 'dnsimple-java'

java {
    sourceCompatibility = '1.17'
    targetCompatibility = '1.17'

    withJavadocJar()
    withSourcesJar()
}

ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = group
            artifactId = description
            version = version

            from components.java

            pom {
                name = 'dnsimple-java'
                description = 'DNSimple Java Bindings'
                url = 'https://github.com/dnsimple/dnsimple-java'
                properties = [:]
                licenses {
                    license {
                        name = 'MIT'
                        url = 'http://choosealicense.com/licenses/mit/'
                    }
                }
                organization {
                    name = 'DNSimple'
                    url = 'https://dnsimple.com'
                }
                developers {
                    developer {
                        name = 'DNSimple'
                        email = 'support@dnsimple.com'
                        organization = 'DNSimple'
                        organizationUrl = 'https://dnsimple.com'
                    }
                }
                scm {
                    connection = 'scm:git:git@github.com:dnsimple/dnsimple-java.git'
                    developerConnection = 'scm:git:git@github.com:dnsimple/dnsimple-java.git'
                    url = 'git@github.com:dnsimple/dnsimple-java.git'
                }
            }
        }
    }
}

signing {
    def signingKeyId = findProperty("signingKeyId")
    def signingKey = findProperty("signingKey")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
    sign publishing.publications.mavenJava
}

nexusPublishing {
    repositories {
        sonatype()
    }
}

tasks.withType(Sign) {
    onlyIf { isReleaseVersion }
}

test {
    testLogging {
        exceptionFormat = 'full'
    }
}