-
Notifications
You must be signed in to change notification settings - Fork 5
/
UVersionCheck.pas
78 lines (64 loc) · 1.56 KB
/
UVersionCheck.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
unit UVersionCheck;
interface
procedure CheckMyVersion;
implementation
uses UVars, System.Net.HttpClient, System.JSON, Vcl.Dialogs,
System.SysUtils, System.UITypes, System.Classes,
Winapi.ShellAPI, Winapi.Windows;
const URL_GITHUB = 'https://api.github.com/repos/digao-dalpiaz/Updater/releases/latest';
type
TThCheck = class(TThread)
protected
procedure Execute; override;
private
procedure Check;
end;
procedure TThCheck.Check;
var
H: THTTPClient;
Res, tag_version, tag_url: string;
data: TJSONObject;
begin
H := THTTPClient.Create;
try
Res := H.Get(URL_GITHUB).ContentAsString;
finally
H.Free;
end;
data := TJSONObject.ParseJSONValue(Res) as TJSONObject;
try
if data.GetValue('id') = nil then
raise Exception.Create('Latest release not found');
tag_version := data.GetValue('tag_name').Value;
tag_url := data.GetValue('html_url').Value;
finally
data.Free;
end;
if 'v'+STR_VERSION<>tag_version then
begin
Synchronize(procedure
begin
if MessageDlg(Format('New version %s available. Do you want to download it?', [tag_version]), mtInformation, mbYesNo, 0) = mrYes then
ShellExecute(0, '', PChar(tag_url), '', '', SW_SHOWNORMAL);
end);
end;
end;
procedure TThCheck.Execute;
begin
inherited;
FreeOnTerminate := True;
try
Check;
except
on E: Exception do
Synchronize(procedure
begin
MessageDlg('Error checking version updates: '+E.Message, mtError, [mbOK], 0);
end);
end;
end;
procedure CheckMyVersion;
begin
TThCheck.Create;
end;
end.