-
Notifications
You must be signed in to change notification settings - Fork 8
/
build.gradle.kts
135 lines (123 loc) · 3.98 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
plugins {
kotlin("multiplatform") version "2.0.0"
id("com.gorylenko.gradle-git-properties") version "2.4.1"
id("org.gradlewebtools.minify") version "1.3.2"
`maven-publish`
}
group = "ch.derlin"
version = "2.2.1-SNAPSHOT" // x-release-please-version
repositories {
mavenCentral()
}
java {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8
}
kotlin {
jvm {
compilations.all {
kotlinOptions.jvmTarget = "1.8"
}
testRuns["test"].executionTask.configure {
useJUnitPlatform()
}
withJava()
// https://stackoverflow.com/a/61433514
val jvmJar by tasks.getting(org.gradle.jvm.tasks.Jar::class) {
duplicatesStrategy = DuplicatesStrategy.WARN
doFirst {
manifest {
attributes["Main-Class"] = "ch.derlin.bitdowntoc.MainKt"
}
from(configurations.getByName("runtimeClasspath").map { if (it.isDirectory) it else zipTree(it) })
}
}
}
js(IR) {
moduleName = "bitdowntoc" // name of the generated .js file
browser {
binaries.executable()
distribution {
outputDirectory = file("$projectDir/build/web")
}
}
}
sourceSets {
val commonMain by getting
val commonTest by getting {
dependencies {
implementation(kotlin("test-common"))
implementation(kotlin("test-annotations-common"))
}
}
val jvmMain by getting {
dependencies {
implementation("com.github.ajalt.clikt:clikt:4.2.2")
}
resources.setSrcDirs(resources.srcDirs.plus(project.layout.buildDirectory.dir("version")))
}
val jvmTest by getting {
dependencies {
implementation(kotlin("test-junit5"))
implementation("org.junit.jupiter:junit-jupiter-api:5.10.2")
runtimeOnly("org.junit.jupiter:junit-jupiter-engine:5.10.2")
implementation("com.willowtreeapps.assertk:assertk-jvm:0.28.1")
}
}
val jsMain by getting {
// build/css populated via minification, see minification task
resources.setSrcDirs(resources.srcDirs.plus("$projectDir/build/css"))
}
val jsTest by getting {
dependencies {
implementation(kotlin("test-js"))
}
}
}
}
// Minify the CSS
// For it to work: (a) move the CSS file outside of resources (so it isn't copied to the prod bundle),
// (b) add the minification output task to the jsMain.resources.srcSets, (c) ensure the build/css output
// is generated *before* JS process resources.
minification {
css {
srcDir = project.file("$projectDir/src/jsMain/css")
dstDir = project.file("$projectDir/build/css")
}
}
tasks.named("jsProcessResources") {
dependsOn += "cssMinify"
}
gitProperties {
// It is currently not possible to read properties files from JS, so only do this in JVM
gitPropertiesResourceDir.set(project.layout.buildDirectory.dir("version"))
keys = listOf(
"git.build.version",
"git.branch",
"git.commit.id",
"git.commit.message.short",
"git.commit.time",
"git.dirty"
)
}
tasks.named("jvmProcessResources").configure { dependsOn("generateGitProperties") }
tasks.register("bitdowntoc") {
dependsOn("generateGitProperties", "jvmJar", "jsBrowserDistribution")
}
publishing {
publications {
create<MavenPublication>("default") {
//from(components["java"])
}
}
repositories {
maven {
name = "GitHubPackages"
url = uri("https://maven.pkg.github.com/derlin/bitdowntoc")
credentials {
username = System.getenv("GITHUB_ACTOR")
password = System.getenv("GITHUB_TOKEN")
}
}
}
}