build.gradle

task publish

task wrapper(type: Wrapper) {
	gradleVersion = '1.10'
	distributionUrl = 'http://services.gradle.org/distributions/gradle-1.10-all.zip'
}

buildscript {
	repositories {
		mavenCentral()
	}
	
	dependencies {
		classpath 'nl.javadude.gradle.plugins:license-gradle-plugin:0.6.0'
	}
}

ext {
	encoding = 'UTF-8'
}

allprojects {
	apply plugin: 'eclipse'
	tasks.eclipse << {
		File prefs = project.file('.settings/org.eclipse.core.resources.prefs');
		if(!prefs.exists()) {
			prefs.parentFile.mkdirs()
			project.file('.settings/org.eclipse.core.resources.prefs')<< "eclipse.preferences.version=1\nencoding/<project>=$encoding\n";
		}
	}
}

subprojects {
	apply plugin: 'java'
	apply plugin: 'maven-publish'
	apply plugin: 'license'
	
	sourceCompatibility = 1.6
	targetCompatibility = 1.6
	
	license {
		ext.year = Calendar.getInstance().get(Calendar.YEAR)
		ext.name = 'Steffen Schaefer'
		header rootProject.file('LICENSE')
	}

	repositories { mavenCentral() }

	dependencies {
		compile gradleApi()
		testCompile group: 'junit', name: 'junit', version: '[4.11,5.0['
	}
	
	tasks.withType(Compile) {
		options.encoding = rootProject.encoding
	}
	
	task sourceJar(type: Jar) {
		from sourceSets.main.allJava
	}
	
	task javadocJar (type: Jar, dependsOn: javadoc) {
		from javadoc.destinationDir
	}
	
	javadoc {
		options {
			links 'http://www.gradle.org/docs/current/javadoc/', 'http://docs.oracle.com/javase/6/docs/api/'
		}
	}

	group='de.richsource.gradle.plugins'
	version='0.4-SNAPSHOT'
	publishing {
		publications {
			mavenJava(MavenPublication) {
				from components.java
				artifact javadocJar { classifier = 'javadoc' }
				artifact sourceJar { classifier = 'sources' }
				pom.withXml {
					def root = asNode()
	                root.appendNode('name', 'Gradle GWT plugin')
	                root.appendNode('description', 'Gradle plugin to support GWT related tasks.')
	                root.appendNode('inceptionYear', '2013')
					def license = root.appendNode('licenses').appendNode('license')
					license.appendNode('name', 'Apache License, Version 2.0')
					license.appendNode('url', 'http://www.apache.org/licenses/LICENSE-2.0.txt')
				}
			}
		}
		repositories {
			maven {
				url new File(rootProject.projectDir, 'repo').toURI()
			}
		}
	}

	rootProject.tasks.publish.dependsOn project.tasks.publish
}