Missing sources when trying to import unicode-org/icu

[ddassie-texa]

I'm trying to compile https://github.com/unicode-org/icu.git from source using Bazel 7.3, my project is using the bzlmod system and I'm trying to get the sources for icu using bazel_dep, in my MODULE.bazel I have defined this:

bazel_dep(name = "rules_foreign_cc", version = "0.12.0")

_ALL_CONTENT = """\
filegroup(
    name = "all_srcs",
    srcs = glob(["**"]),
    visibility = ["//visibility:public"],
)
"""

http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
http_archive(
    name = "icu",
    url = "https://github.com/unicode-org/icu/releases/download/release-75-1/icu4c-75_1-src.tgz",
    sha256 = "cb968df3e4d2e87e8b11c49a5d01c787bd13b9545280fc6642f826527618caef",
    strip_prefix = "icu/source",
    build_file_content = _ALL_CONTENT
)

Than I have a BUILD.bazel file in "./libs/icu/BUILD.bazel" with the following content:

load("@rules_foreign_cc//foreign_cc:defs.bzl", "configure_make")

configure_make(
    name = "icu",
    configure_in_place = True,
    lib_source = "@icu//:all_srcs",
)

and I build with:
bazel build --sandbox_debug //libs/icu
but the build fails, it says: error: cannot find sources (common/unicode/utypes.h), if I look inside the sandbox the entire "common/" directory is missing, but if I extract the tar by hand everything is fine so clearly Bazel is doing something strage, I initially thought it was because of the presence of some BUILD.bazel files, so I added a patch in http_archive to remove them but the issue still persists.

Does anyone know why I'm missing files or even if there is a better way for me to compile ICU using Bazel?

[gramic]

You are on the right path.

1. You should delete all BAZEL.build files in all sub directories with a patch.
2. Do not strip the source because the LICENSE file is in the root icu directory.
   This is the correct line.

strip_prefix = "icu",

3. Disable more things you don't need. Found from this repo https://github.com/google/zetasql/blob/master/bazel/icu.BUILD

configure_make(
    name = "icu",
    args = ["-j16"],
    configure_command = "source/configure",
    configure_in_place = True,
    configure_options = [
        "--enable-option-checking",
        "--enable-static",
        "--enable-tools",  # needed to build data
        "--disable-shared",
        "--disable-dyload",
        "--disable-extras",
        "--disable-plugins",
        "--disable-tests",
        "--disable-samples",
        "--with-data-packaging=static",
    ],
    lib_source = ":all_srcs",
    out_static_libs = [
        "libicudata.a",
        "libicui18n.a",
        "libicuio.a",
        "libicutu.a",
        "libicuuc.a",
    ],
)