build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'com.diffplug.spotless' version '6.11.0'
}

repositories {
    mavenCentral()
    maven {
        url 'https://s01.oss.sonatype.org/content/repositories/releases/'
    }
}

dependencies {
    api 'com.squareup.okhttp3:okhttp:4.12.0'
    api 'com.fasterxml.jackson.core:jackson-databind:2.17.2'
    api 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.17.2'
    api 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.17.2'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
}


sourceCompatibility = 1.8
targetCompatibility = 1.8

tasks.withType(Javadoc) {
    failOnError false
    options.addStringOption('Xdoclint:none', '-quiet')
}

spotless {
    java {
        palantirJavaFormat()
    }
}


java {
    withSourcesJar()
    withJavadocJar()
}


group = 'dev.vapi'

version = '0.4.0'

jar {
    dependsOn(":generatePomFileForMavenPublication")
    archiveBaseName = "server-sdk"
}

sourcesJar {
    archiveBaseName = "server-sdk"
}

javadocJar {
    archiveBaseName = "server-sdk"
}

test {
    useJUnitPlatform()
    testLogging {
        showStandardStreams = true
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = 'dev.vapi'
            artifactId = 'server-sdk'
            version = '0.4.0'
            from components.java
            pom {
                licenses {
                    license {
                        name = 'The MIT License (MIT)'
                        url = 'https://mit-license.org/'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/VapiAI/server-sdk-java.git'
                    developerConnection = 'scm:git:git://github.com/VapiAI/server-sdk-java.git'
                    url = 'https://github.com/VapiAI/server-sdk-java'
                }
            }
        }
    }
    repositories {
        maven {
            url "$System.env.MAVEN_PUBLISH_REGISTRY_URL"
            credentials {
                username "$System.env.MAVEN_USERNAME"
                password "$System.env.MAVEN_PASSWORD"
            }
        }
    }
}