build.gradle

plugins {
    id "fabric-loom" version "1.2-SNAPSHOT"
}

def packageJson = new groovy.json.JsonSlurper().parseText(file("package.json").text)
version = packageJson.version
group = project.maven_group

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    // modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    compileOnly "org.projectlombok:lombok:1.18.20"
    annotationProcessor "org.projectlombok:lombok:1.18.20"
}

loom {
    accessWidenerPath = file("src/main/resources/kze_plus.accesswidener")
}

base {
    archivesName = project.archives_base_name
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 17
}

java {
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

tasks.register("copyArtifact", Copy) {
    dependsOn remapJar

    from remapJar.archiveFile
    into "${buildDir}/artifacts"
}

build {
    dependsOn copyArtifact
}