build.gradle

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: 'maven'

group = 'net.minecraftforge.gradle'
version = '1.3-SNAPSHOT'
archivesBaseName = 'ForgeGradle'
targetCompatibility = '1.6'
sourceCompatibility = '1.6'

repositories {
    mavenLocal()
    maven {
        name = "forge"
        url = "http://files.minecraftforge.net/maven"
    }
	maven {
		// because Srg2Source needs an eclipse dependency.
		name = "eclipse"
		url = "https://repo.eclipse.org/content/groups/eclipse/"
	}
    maven {
		// because SpecialSource doesnt have a full release
        name = "sonatype"
        url = "https://oss.sonatype.org/content/repositories/snapshots/"
    }
    mavenCentral()
}

jar {
    manifest {
        attributes 'version':project.version, 'javaCompliance': project.targetCompatibility
        attributes 'group':project.group
    }
}

configurations {
    deployerJars
}

dependencies {
    compile gradleApi()
    
    // moved to the beginning to be the overrider
    compile 'org.ow2.asm:asm-debug-all:4.1' // Debug version, so we can have generics!

    compile 'net.sourceforge.argo:argo:3.4' // json stuff? perhaps replace with json slurper and stuff?
    compile 'net.sf.opencsv:opencsv:2.3' // reading CSVs.. also used by SpecialSource
    compile 'com.cloudbees:diff4j:1.1' // for difing and patching
    compile 'com.github.abrarsyed.jastyle:jAstyle:1.2' // formatting

    compile 'com.github.jponge:lzma-java:1.3' // replaces the LZMA binary
    compile 'com.nothome:javaxdelta:2.0.1' // GDIFF implementation for BinPatches
    compile 'com.google.code.gson:gson:2.2.4' // Used instead of Argo for buuilding changelog.
    compile 'com.github.tony19:named-regexp:0.2.3' // 1.7 Named regexp features
    
    compile 'net.md-5:SpecialSource:1.7-SNAPSHOT' // deobf and reobs
    
    // mcp stuff
    compile 'de.oceanlabs.mcp:RetroGuard:3.6.6'
    compile 'de.oceanlabs.mcp:mcinjector:3.2-SNAPSHOT'
    compile 'net.minecraftforge.srg2source:Srg2Source:3.2-SNAPSHOT'

    // stupid maven
    deployerJars "org.apache.maven.wagon:wagon-ssh:2.2"
}

artifacts { archives jar }

uploadArchives {
    repositories {
        if (project.hasProperty("filesmaven")) {
            logger.info('Publishing to files server')

            mavenDeployer {
                configuration = configurations.deployerJars

                repository(url: project.filesmaven.url) {
                    authentication(userName: project.filesmaven.username, privateKey: project.filesmaven.key)
                }

                pom {
                    groupId = project.group
                    version = project.version
                    artifactId = project.archivesBaseName
                    project {
                        name project.archivesBaseName
                        packaging 'jar'
                        description 'Gradle plugin for Forge'
                        url 'https://github.com/MinecraftForge/ForgeGradle'

                        scm {
                            url 'https://github.com/MinecraftForge/ForgeGradle'
                            connection 'scm:git:git://github.com/MinecraftForge/ForgeGradle.git'
                            developerConnection 'scm:git:git@github.com:MinecraftForge/ForgeGradle.git'
                        }

                        issueManagement {
                            system 'github'
                            url 'https://github.com/MinecraftForge/ForgeGradle/issues'
                        }

                        licenses {
                            license {
                                name 'Eclipse Public License (EPL), Version 1.0'
                                url 'http://www.eclipse.org/legal/epl-v10.html'
                                distribution 'repo'
                            }
                        }

                        developers {
                            developer {
                                id 'AbrarSyed'
                                name 'Abrar Syed'
                                roles { role 'developer' }
                            }
                        }
                        developers {
                            developer {
                                id 'LexManos'
                                name 'Lex Manos'
                                roles { role 'developer' }
                            }
                        }
                    }
                }
            }
        }
        else
        {
            add project.repositories.mavenLocal()
        }
    }
}