Sleep mode for Tiny3227 example?

[Uwne]

Hi,

does anyone has an example to set the Tiny3227 into power down mode and wake up by a button?
In my project I use the Pins PA2, PA3 and PA4 (19,20,0).

Uwe

[SpenceKonde]

Should be as simple as setting up a pin interrupt on change or low level (rising and falling work too but only on pins 2 and 6 with in each port), going to sleep, and then waking ip by pressing to the button, and then putting the part to sleep. Pretty see the PinInterrupts and PowerSave documents in /megaavr/extras in the repo should give you want you need to know.

If you've been trying with attachInterrupt, that's part of the problem - I've fixed the bug but none of the people who have test cases that reproduce the bug have gotten back to me about whether I fixed it. Currently it only works if the Old Version option is selected from tools -> attachInterruptMode

The next release (2.5.11) will fix that, and it's in github, just not a release. I don't trust myself to test it since, well, this is version 2.5.11, and 9 of the past 10 releases have been "CRITICAL BUGFIX" to correct attachInterrupt. So clearly I don't have a good test case....

Though, I wouldn't use attachInterrupt for a wake interrupt unless I had a gun to my head -

This should be straightforward:

#include <avr/sleep.h>

volatile byte lastwakepin=0

//Before entering sleep mode, the desired sleep mode must be selected with set_sleep_mode():
void setup() {
  pinMode(PIN_PA7,OUTPUT); //LED for diagnosics
  pinMode(PIN_PA2,INPUT_PULLUP);
  pinMode(PIN_PA3,INPUT_PULLUP);
  pinMode(PIN_PA4,INPUT_PULLUP);
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
/* You want sleep mode power down or sleep mode standby. Standby is almost the same power consumption as power down (unlike classic AVRs where it just ain't even worth doing) if you turn off all the peripherals..... but you can also selectively leave on peripherals if you want (if it needs the system clock running though, that greatly increases the power consumption). But they made standby way the hell better. Any peripheral with a RUNSTBY bit in it's CTRLA can be made to run in standby (that's most of them), but none of them have to be. 
*/
}

void loop() {
  if (lastwakepins == 0) {
    Serial.println("fresh start, have not woken up");
  } else {
    Serial.print("Woken by pin(s)")'
    for (uint8_t i = 0; i < 8; i++) {
      if (lastwakepins & (1 <<  i)) {
        Serial.print(i); 
        Serial.print(" "); //allow for multiple pins to have triggered int and notify you of that odd occurrence. 
      }
   }
  Serial.println(); 
  goToSleep(); 
}
    
void gotToSleep() {
  Serial.flush(); // wait until we're done sending everything, otherwise the serial prints won't come out
  // Enable the interrupts. 
  PORTA.PIN2CTRL.|= PORT_ISC_CHANGE_gc; // int on change. 
  PORTA.PIN3CTRL.|= PORT_ISC_CHANGE_gc; 
  PORTA.PIN4CTRL.|= PORT_ISC_CHANGE_gc;
  sleep_enable(); //Unlocks the sleep instruction to prevent software bugs from putting the chip top sleep without a way to wake it up
  sleep_cpu();      // after the interrupt that wakes it finishes, you'll be here
  PORTA.PIN2CTRL. &= PORT_ISC_gm; 
  PORTA.PIN3CTRL. &= PORT_ISC_gm; // these clear the input sense configuration bits without unsetting the pullup enable bit
  PORTA.PIN4CTRL. &= PORT_ISC_gm;
  while ((PORTA.IN & 0b00011100) != 0b00011100); // wait until the buttons are released, if they're not already 
  sleep_disable(); 
}
  
ISR(PORTA_PORT_vect) {
  uint8_t flags = PORTA.INTFLAGS; //read which pins triggered he int
  lastwakepins = flags;                    // store it in the volatile variable for loop to display
  PORTA.INTFLAGS = flags;            // Clear the flags by writing a 1 to them (not a 0);
  PORTA.OUTTGL = 0x80; // toggle PA7 which i set output (connect it to an LED) 
}

See also: https://github.com/SpenceKonde/megaTinyCore/blob/master/megaavr/extras/PinInterrupts.md https://github.com/SpenceKonde/megaTinyCore/blob/master/megaavr/extras/PowerSave.md and https://github.com/SpenceKonde/megaTinyCore/blob/master/megaavr/extras/Ref_Interrupts.md
Lot of ways you can configure this to tweak the behavior to match your needs. .

[Uwne]

Wow … thank you very much. I will test everything by tomorrow and come back to you with my results.

[Uwne]

Your code works very well, thanks again. I just need to replace some typos and add a brace in the loop.

Here is the working code.

#include <avr/sleep.h>

volatile byte lastwakepins=0;

void setup() {   
  Serial.begin(57600);
  
  pinMode(PIN_PA2,INPUT_PULLUP);
  pinMode(PIN_PA3,INPUT_PULLUP);
  pinMode(PIN_PA4,INPUT_PULLUP);
  pinMode(PIN_PB0,OUTPUT);
  
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);  
  
/* You want sleep mode power down or sleep mode standby. Standby is almost the same power consumption as power down
 * (unlike classic AVRs where it just ain't even worth doing) if you turn off all the peripherals..... 
 * but you can also selectively leave on peripherals if you want (if it needs the system clock running though, 
 * hat greatly increases the power consumption). But they made standby way the hell better. 
 * Any peripheral with a RUNSTBY bit in it's CTRLA can be made to run in standby (that's most of them),
 * but none of them have to be. 
*/  
 }

void loop() {
  if (lastwakepins == 0) {
      Serial.println("fresh start, have not woken up");
    } else {
      Serial.print("Woken by pin(s)");
      for (uint8_t i = 0; i < 8; i++) {
        if (lastwakepins & (1 <<  i)) {
          Serial.print(i); 
          Serial.print(" "); //allow for multiple pins to have triggered int and notify you of that odd occurrence. 
              }
            }
          }
  Serial.println(); 
  goToSleep(); 
}


void goToSleep() {
  Serial.flush(); // wait until we're done sending everything, otherwise the serial prints won't come out
  // Enable the interrupts. 
  PORTA.PIN2CTRL |= PORT_ISC_FALLING_gc; // int on change. 
  PORTA.PIN3CTRL |= PORT_ISC_FALLING_gc; 
  PORTA.PIN4CTRL |= PORT_ISC_FALLING_gc;  
  sleep_enable();   //Unlocks the sleep instruction to prevent software bugs from putting the chip top sleep without a way to wake it up
  sleep_cpu();      // after the interrupt that wakes it finishes, you'll be here
  PORTA.PIN2CTRL &= PORT_ISC_gm; 
  PORTA.PIN3CTRL &= PORT_ISC_gm; // these clear the input sense configuration bits without unsetting the pullup enable bit
  PORTA.PIN4CTRL &= PORT_ISC_gm;
  while ((PORTA.IN & 0b00011100) != 0b00011100); // wait until the buttons are released, if they're not already 
  sleep_disable(); 
}


ISR(PORTA_PORT_vect) {
  uint8_t flags = PORTA.INTFLAGS;  // read which pins triggered the int
  lastwakepins = flags;            // store it in the volatile variable for loop to display
  PORTA.INTFLAGS = flags;          // Clear the flags by writing a 1 to them (not a 0);
  PORTB.OUTTGL = 0x1;              // toggle PB0 which i set output (connect it to an LED) 
}

[SpenceKonde]

Great, glad to help - like I said, I was writing that off the top of my head in the forum, so if I only made a few syntax errors, that's pretty good for me.