From 78e82bb24a909e4d5800d29bf39bf2d64ead1358 Mon Sep 17 00:00:00 2001
From: awwpotato <awwpotato@voidq.com>
Date: Tue, 21 Jan 2025 14:20:19 -0800
Subject: [PATCH] slacky: init at 0.0.5

---
 pkgs/by-name/sl/slacky/package.nix | 66 ++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 pkgs/by-name/sl/slacky/package.nix

diff --git a/pkgs/by-name/sl/slacky/package.nix b/pkgs/by-name/sl/slacky/package.nix
new file mode 100644
index 00000000000000..832e847344ccf9
--- /dev/null
+++ b/pkgs/by-name/sl/slacky/package.nix
@@ -0,0 +1,66 @@
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  electron,
+  copyDesktopItems,
+  makeDesktopItem,
+}:
+buildNpmPackage rec {
+  pname = "slacky";
+  version = "0.0.5";
+
+  src = fetchFromGitHub {
+    owner = "andirsun";
+    repo = "Slacky";
+    tag = "v${version}";
+    hash = "sha256-nDxmzZqi7xEe4hnY6iXJg+613lSKElWxvF3w8bRDW90=";
+  };
+
+  npmDepsHash = "sha256-9+4cxeQw2Elug+xIgzNvpaSMgDVlBFz/+TW1jJwDm40=";
+
+  npmPackFlags = [ "--ignore-scripts" ];
+
+  NODE_OPTIONS = "--openssl-legacy-provider";
+
+  nativeBuildInputs = [
+    electron
+    copyDesktopItems
+  ];
+
+  env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
+
+  postInstall = ''
+    mkdir -p $out/share/icons
+    ln -s $out/lib/node_modules/${pname}/build/icons/icon.png $out/share/icons/${pname}.png
+    makeWrapper ${electron}/bin/electron $out/bin/${pname} \
+      --add-flags $out/lib/node_modules/${pname}/
+  '';
+
+  desktopItems = lib.singleton (makeDesktopItem {
+    name = "slacky";
+    exec = "slacky %u";
+    icon = "slacky";
+    desktopName = "Slacky";
+    comment = "An unofficial Slack desktop client for arm64 Linux";
+    startupWMClass = "com.andersonlaverde.slacky";
+    type = "Application";
+    categories = [
+      "Network"
+      "InstantMessaging"
+    ];
+    mimeTypes = [
+      "x-scheme-handler/slack"
+    ];
+  });
+
+  meta = {
+    description = "Unofficial Slack desktop client for arm64 Linux";
+    homepage = "https://github.com/andirsun/Slacky";
+    changelog = "https://github.com/andirsun/Slacky/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ awwpotato ];
+    platforms = [ "aarch64-linux" ];
+    mainProgram = "slacky";
+  };
+}