build.gradle

subprojects {
	apply plugin: 'java'

	java.toolchain.languageVersion = JavaLanguageVersion.of(17)
	java.withSourcesJar()
	java.withJavadocJar()

	configurations {
		testCompileOnly.extendsFrom compileOnly
	}

	jar {
		from(rootProject.file("LICENSE.md")) {
			rename { "LICENSE_${mod_name}.md" }
		}
		manifest {
			attributes([
				"Specification-Title": mod_name,
				"Specification-Vendor": mod_author,
				"Specification-Version": project.jar.archiveVersion,
				"Implementation-Title": project.name,
				"Implementation-Version": project.jar.archiveVersion,
				"Implementation-Vendor": mod_author,
				"Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
				"Timestamp": System.currentTimeMillis(),
				"Built-On-Java": "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
				"Built-On-Minecraft": minecraft_version
			])
		}
	}

	sourcesJar {
		from(rootProject.file("LICENSE.md")) {
			rename { "LICENSE_${mod_name}.md" }
		}
	}

	repositories {
		mavenCentral()

		maven {
			name = 'Sponge / Mixin'
			url = 'https://repo.spongepowered.org/repository/maven-public/'
		}

		maven {
			url = "https://api.modrinth.com/maven/"
			content {
				includeGroup "maven.modrinth"
			}
		}

		maven {
			url "https://jm.gserv.me/repository/maven-public/"
			content {
				includeGroup "info.journeymap"
			}
		}

		maven {
			url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/"
			content {
				includeGroup "net.minecraftforge"
			}
		}

		maven {
			name = "Fuzs Mod Resources"
			url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/"
		}
	}

	tasks.withType(JavaCompile).configureEach {
		it.options.encoding = 'UTF-8'
		it.options.release = 17
	}

	// Disables Gradle's custom module metadata from being published to maven. The
	// metadata includes mapped dependencies which are not reasonably consumable by
	// other mod developers.
	tasks.withType(GenerateModuleMetadata) {
		enabled = false
	}
}