build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'
apply plugin: "curseforge"
apply plugin: "maven-publish"

ext.configFile = file "build.properties"

configFile.withReader {
    // read config.  it shall from now on be referenced as simply config or as project.config
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

def buildversion = '0'

if (hasProperty("teamcity")) {
    buildversion = teamcity["build.number"]
}

sourceCompatibility = JavaVersion.VERSION_1_6
targetCompatibility = JavaVersion.VERSION_1_6

version = "${config.mod_version}"
group= "com.fireball1725.defaultworldgenerator" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "DefaultWorldGenerator"

minecraft {
    version = "${config.minecraft_version}-${config.forge_version}"
    runDir = "eclipse"

    replaceIn "lib/Reference.java"
    replace "@VERSION@", "${config.mod_version}-b"+buildversion
    replace "@BUILDNUMBER@", buildversion

    replaceIn "DefaultWorldGenerator.java"
    replace "@DEBUG@", "somethingthatisnot-@DEBUG@"
}

version = "${config.minecraft_version}-"+version+"-b"+buildversion

configurations {
    shade
    //include it in compile
    compile.extendsFrom shade
}

dependencies {
    // you may put jars on which you depend on in ./libs
    // or you may define them like so..
    //compile "some.group:artifact:version:classifier"
    //compile "some.group:artifact:version"

    // real examples
    //compile 'com.mod-buildcraft:buildcraft:6.0.8:dev'  // adds buildcraft to the dev env
    //compile 'com.googlecode.efficient-java-matrix-library:ejml:0.24' // adds ejml to the dev env
    shade 'com.github.nkzawa:socket.io-client:0.3.0'

    // for more info...
    // http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
    // http://www.gradle.org/docs/current/userguide/dependency_management.html

}

jar {
    configurations.shade.each { dep ->
        from(project.zipTree(dep)) {
            exclude 'META-INF', 'META-INF/**'
        }
    }
}

processResources
        {
            // this will ensure that this task is redone when the versions change.
            inputs.property "version", project.version
            inputs.property "mcversion", project.minecraft.version

            // replace stuff in mcmod.info, nothing else
            from(sourceSets.main.resources.srcDirs) {
                include 'mcmod.info'

                // replace version and mcversion
                expand 'version':project.version, 'mcversion':project.minecraft.version
            }

            // copy everything else, thats not the mcmod.info
            from(sourceSets.main.resources.srcDirs) {
                exclude 'mcmod.info'
            }
        }

//Add universal identifier to jar name
jar {
    classifier = 'universal'
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'deobf'
}

task sourceJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'source'
}

artifacts {
    archives deobfJar
}

curse {
    apiKey = project.fireball1725curse
    projectId = "226188"
    changelog = file("build/libs/changelog.txt").text
    releaseType = "release"
    addGameVersion "1.7.10"
}

build.dependsOn sourceJar